001:       REAL FUNCTION SLA_GERCOND ( TRANS, N, A, LDA, AF, LDAF, IPIV,
002:      $                            CMODE, C, INFO, WORK, IWORK )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          TRANS
016:       INTEGER            N, LDA, LDAF, INFO, CMODE
017: *     ..
018: *     .. Array Arguments ..
019:       INTEGER            IPIV( * ), IWORK( * )
020:       REAL               A( LDA, * ), AF( LDAF, * ), WORK( * ),
021:      $                   C( * )
022: *
023: *     SLA_GERCOND estimates the Skeel condition number of op(A) * op2(C)
024: *     where op2 is determined by CMODE as follows
025: *     CMODE =  1    op2(C) = C
026: *     CMODE =  0    op2(C) = I
027: *     CMODE = -1    op2(C) = inv(C)
028: *     The Skeel condition number cond(A) = norminf( |inv(A)||A| )
029: *     is computed by computing scaling factors R such that
030: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
031: *     infinity-norm condition number.
032: *     WORK is a REAL workspace of size 3*N, and
033: *     IWORK is an INTEGER workspace of size N.
034: *     ..
035: *     .. Local Scalars ..
036:       LOGICAL            NOTRANS
037:       INTEGER            KASE, I, J
038:       REAL               AINVNM, TMP
039: *     ..
040: *     .. Local Arrays ..
041:       INTEGER            ISAVE( 3 )
042: *     ..
043: *     .. External Functions ..
044:       LOGICAL            LSAME
045:       EXTERNAL           LSAME
046: *     ..
047: *     .. External Subroutines ..
048:       EXTERNAL           SLACN2, SGETRS, XERBLA
049: *     ..
050: *     .. Intrinsic Functions ..
051:       INTRINSIC          ABS, MAX
052: *     ..
053: *     .. Executable Statements ..
054: *
055:       SLA_GERCOND = 0.0
056: *
057:       INFO = 0
058:       NOTRANS = LSAME( TRANS, 'N' )
059:       IF ( .NOT. NOTRANS .AND. .NOT. LSAME(TRANS, 'T')
060:      $     .AND. .NOT. LSAME(TRANS, 'C') ) THEN
061:          INFO = -1
062:       ELSE IF( N.LT.0 ) THEN
063:          INFO = -2
064:       END IF
065:       IF( INFO.NE.0 ) THEN
066:          CALL XERBLA( 'SLA_GERCOND', -INFO )
067:          RETURN
068:       END IF
069:       IF( N.EQ.0 ) THEN
070:          SLA_GERCOND = 1.0
071:          RETURN
072:       END IF
073: *
074: *     Compute the equilibration matrix R such that
075: *     inv(R)*A*C has unit 1-norm.
076: *
077:       IF (NOTRANS) THEN
078:          DO I = 1, N
079:             TMP = 0.0
080:             IF ( CMODE .EQ. 1 ) THEN
081:                DO J = 1, N
082:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
083:                END DO
084:             ELSE IF ( CMODE .EQ. 0 ) THEN
085:                DO J = 1, N
086:                   TMP = TMP + ABS( A( I, J ) )
087:                END DO
088:             ELSE
089:                DO J = 1, N
090:                   TMP = TMP + ABS( A( I, J ) / C( J ) )
091:                END DO
092:             END IF
093:             WORK( 2*N+I ) = TMP
094:          END DO
095:       ELSE
096:          DO I = 1, N
097:             TMP = 0.0
098:             IF ( CMODE .EQ. 1 ) THEN
099:                DO J = 1, N
100:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
101:                END DO
102:             ELSE IF ( CMODE .EQ. 0 ) THEN
103:                DO J = 1, N
104:                   TMP = TMP + ABS( A( J, I ) )
105:                END DO
106:             ELSE
107:                DO J = 1, N
108:                   TMP = TMP + ABS( A( J, I ) / C( J ) )
109:                END DO
110:             END IF
111:             WORK( 2*N+I ) = TMP
112:          END DO
113:       END IF
114: *
115: *     Estimate the norm of inv(op(A)).
116: *
117:       AINVNM = 0.0
118: 
119:       KASE = 0
120:    10 CONTINUE
121:       CALL SLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
122:       IF( KASE.NE.0 ) THEN
123:          IF( KASE.EQ.2 ) THEN
124: *
125: *           Multiply by R.
126: *
127:             DO I = 1, N
128:                WORK(I) = WORK(I) * WORK(2*N+I)
129:             END DO
130: 
131:             IF (NOTRANS) THEN
132:                CALL SGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
133:      $            WORK, N, INFO )
134:             ELSE
135:                CALL SGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
136:      $            WORK, N, INFO )
137:             END IF
138: *
139: *           Multiply by inv(C).
140: *
141:             IF ( CMODE .EQ. 1 ) THEN
142:                DO I = 1, N
143:                   WORK( I ) = WORK( I ) / C( I )
144:                END DO
145:             ELSE IF ( CMODE .EQ. -1 ) THEN
146:                DO I = 1, N
147:                   WORK( I ) = WORK( I ) * C( I )
148:                END DO
149:             END IF
150:          ELSE
151: *
152: *           Multiply by inv(C').
153: *
154:             IF ( CMODE .EQ. 1 ) THEN
155:                DO I = 1, N
156:                   WORK( I ) = WORK( I ) / C( I )
157:                END DO
158:             ELSE IF ( CMODE .EQ. -1 ) THEN
159:                DO I = 1, N
160:                   WORK( I ) = WORK( I ) * C( I )
161:                END DO
162:             END IF
163: 
164:             IF (NOTRANS) THEN
165:                CALL SGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
166:      $            WORK, N, INFO )
167:             ELSE
168:                CALL SGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
169:      $            WORK, N, INFO )
170:             END IF
171: *
172: *           Multiply by R.
173: *
174:             DO I = 1, N
175:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
176:             END DO
177:          END IF
178:          GO TO 10
179:       END IF
180: *
181: *     Compute the estimate of the reciprocal condition number.
182: *
183:       IF( AINVNM .NE. 0.0 )
184:      $   SLA_GERCOND = ( 1.0 / AINVNM )
185: *
186:       RETURN
187: *
188:       END
189: