001:       REAL FUNCTION SLA_GBRCOND( TRANS, N, KL, KU, AB, LDAB, AFB, LDAFB,
002:      $                           IPIV, CMODE, C, INFO, WORK, IWORK )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          TRANS
016:       INTEGER            N, LDAB, LDAFB, INFO, KL, KU, CMODE
017: *     ..
018: *     .. Array Arguments ..
019:       INTEGER            IWORK( * ), IPIV( * )
020:       REAL               AB( LDAB, * ), AFB( LDAFB, * ), WORK( * ),
021:      $                   C( * )
022: *
023: *     SLA_GERCOND Estimates the Skeel condition number of  op(A) * op2(C)
024: *     where op2 is determined by CMODE as follows
025: *     CMODE =  1    op2(C) = C
026: *     CMODE =  0    op2(C) = I
027: *     CMODE = -1    op2(C) = inv(C)
028: *     The Skeel condition number  cond(A) = norminf( |inv(A)||A| )
029: *     is computed by computing scaling factors R such that
030: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
031: *     infinity-norm condition number.
032: *     WORK is a real workspace of size 5*N, and
033: *     IWORK is an integer workspace of size N.
034: *     ..
035: *     .. Local Scalars ..
036:       LOGICAL            NOTRANS
037:       INTEGER            KASE, I, J, KD
038:       REAL               AINVNM, TMP
039: *     ..
040: *     .. Local Arrays ..
041:       INTEGER            ISAVE( 3 )
042: *     ..
043: *     .. External Functions ..
044:       LOGICAL            LSAME
045:       EXTERNAL           LSAME
046: *     ..
047: *     .. External Subroutines ..
048:       EXTERNAL           SLACN2, SGBTRS, XERBLA
049: *     ..
050: *     .. Intrinsic Functions ..
051:       INTRINSIC          ABS, MAX
052: *     ..
053: *     .. Executable Statements ..
054: *
055:       SLA_GBRCOND = 0.0
056: *
057:       INFO = 0
058:       NOTRANS = LSAME( TRANS, 'N' )
059:       IF ( .NOT. NOTRANS .AND. .NOT. LSAME(TRANS, 'T')
060:      $     .AND. .NOT. LSAME(TRANS, 'C') ) THEN
061:          INFO = -1
062:       ELSE IF( N.LT.0 ) THEN
063:          INFO = -2
064:       ELSE IF( KL.LT.0 ) THEN
065:          INFO = -4
066:       ELSE IF( KU.LT.0 ) THEN
067:          INFO = -5
068:       ELSE IF( LDAB.LT.KL+KU+1 ) THEN
069:          INFO = -8
070:       ELSE IF( LDAFB.LT.2*KL+KU+1 ) THEN
071:          INFO = -10
072:       END IF
073:       IF( INFO.NE.0 ) THEN
074:          CALL XERBLA( 'SLA_GBRCOND', -INFO )
075:          RETURN
076:       END IF
077:       IF( N.EQ.0 ) THEN
078:          SLA_GBRCOND = 1.0
079:          RETURN
080:       END IF
081: *
082: *     Compute the equilibration matrix R such that
083: *     inv(R)*A*C has unit 1-norm.
084: *
085:       KD = KU + 1
086:       IF ( NOTRANS ) THEN
087:          DO I = 1, N
088:             TMP = 0.0
089:                IF ( CMODE .EQ. 1 ) THEN
090:                   DO J = 1, N
091:                      IF ( I.GE.MAX( 1, J-KU )
092:      $                    .AND. I.LE.MIN( N, J+KL ) ) THEN
093:                         TMP = TMP + ABS( AB( KD+I-J, J ) * C( J ) )
094:                      END IF
095:                   END DO
096:                ELSE IF ( CMODE .EQ. 0 ) THEN
097:                   DO J = 1, N
098:                      IF ( I.GE.MAX( 1, J-KU )
099:      $                    .AND. I.LE.MIN( N, J+KL ) ) THEN
100:                         TMP = TMP + ABS( AB( KD+I-J, J ) )
101:                      END IF
102:                   END DO
103:                ELSE
104:                   DO J = 1, N
105:                      IF ( I.GE.MAX( 1, J-KU )
106:      $                    .AND. I.LE.MIN( N, J+KL ) ) THEN
107:                         TMP = TMP + ABS( AB( KD+I-J, J ) / C( J ) )
108:                      END IF
109:                   END DO
110:                END IF
111:             WORK( 2*N+I ) = TMP
112:          END DO
113:       ELSE
114:          DO I = 1, N
115:             TMP = 0.0
116:             IF ( CMODE .EQ. 1 ) THEN
117:                DO J = 1, N
118:                   IF ( I.GE.MAX( 1, J-KU )
119:      $                 .AND. I.LE.MIN( N, J+KL ) ) THEN
120:                      TMP = TMP + ABS( AB( J, KD+I-J ) * C( J ) )
121:                   END IF
122:                END DO
123:             ELSE IF ( CMODE .EQ. 0 ) THEN
124:                DO J = 1, N
125:                   IF ( I.GE.MAX( 1, J-KU )
126:      $                 .AND. I.LE.MIN( N, J+KL ) ) THEN
127:                      TMP = TMP + ABS(AB(J,KD+I-J))
128:                   END IF
129:                END DO
130:             ELSE
131:                DO J = 1, N
132:                   IF ( I.GE.MAX( 1, J-KU )
133:      $                 .AND. I.LE.MIN( N, J+KL ) ) THEN
134:                      TMP = TMP + ABS( AB( J, KD+I-J ) / C( J ) )
135:                   END IF
136:                END DO
137:             END IF
138:             WORK( 2*N+I ) = TMP
139:          END DO
140:       END IF
141: *
142: *     Estimate the norm of inv(op(A)).
143: *
144:       AINVNM = 0.0
145: 
146:       KASE = 0
147:    10 CONTINUE
148:       CALL SLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
149:       IF( KASE.NE.0 ) THEN
150:          IF( KASE.EQ.2 ) THEN
151: *
152: *           Multiply by R.
153: *
154:             DO I = 1, N
155:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
156:             END DO
157: 
158:             IF ( NOTRANS ) THEN
159:                CALL SGBTRS( 'No transpose', N, KL, KU, 1, AFB, LDAFB,
160:      $              IPIV, WORK, N, INFO )
161:             ELSE
162:                CALL SGBTRS( 'Transpose', N, KL, KU, 1, AFB, LDAFB, IPIV,
163:      $              WORK, N, INFO )
164:             END IF
165: *
166: *           Multiply by inv(C).
167: *
168:             IF ( CMODE .EQ. 1 ) THEN
169:                DO I = 1, N
170:                   WORK( I ) = WORK( I ) / C( I )
171:                END DO
172:             ELSE IF ( CMODE .EQ. -1 ) THEN
173:                DO I = 1, N
174:                   WORK( I ) = WORK( I ) * C( I )
175:                END DO
176:             END IF
177:          ELSE
178: *
179: *           Multiply by inv(C').
180: *
181:             IF ( CMODE .EQ. 1 ) THEN
182:                DO I = 1, N
183:                   WORK( I ) = WORK( I ) / C( I )
184:                END DO
185:             ELSE IF ( CMODE .EQ. -1 ) THEN
186:                DO I = 1, N
187:                   WORK( I ) = WORK( I ) * C( I )
188:                END DO
189:             END IF
190: 
191:             IF ( NOTRANS ) THEN
192:                CALL SGBTRS( 'Transpose', N, KL, KU, 1, AFB, LDAFB, IPIV,
193:      $              WORK, N, INFO )
194:             ELSE
195:                CALL SGBTRS( 'No transpose', N, KL, KU, 1, AFB, LDAFB,
196:      $              IPIV, WORK, N, INFO )
197:             END IF
198: *
199: *           Multiply by R.
200: *
201:             DO I = 1, N
202:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
203:             END DO
204:          END IF
205:          GO TO 10
206:       END IF
207: *
208: *     Compute the estimate of the reciprocal condition number.
209: *
210:       IF( AINVNM .NE. 0.0 )
211:      $   SLA_GBRCOND = ( 1.0 / AINVNM )
212: *
213:       RETURN
214: *
215:       END
216: