001:       SUBROUTINE SGTTS2( ITRANS, N, NRHS, DL, D, DU, DU2, IPIV, B, LDB )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       INTEGER            ITRANS, LDB, N, NRHS
009: *     ..
010: *     .. Array Arguments ..
011:       INTEGER            IPIV( * )
012:       REAL               B( LDB, * ), D( * ), DL( * ), DU( * ), DU2( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  SGTTS2 solves one of the systems of equations
019: *     A*X = B  or  A'*X = B,
020: *  with a tridiagonal matrix A using the LU factorization computed
021: *  by SGTTRF.
022: *
023: *  Arguments
024: *  =========
025: *
026: *  ITRANS  (input) INTEGER
027: *          Specifies the form of the system of equations.
028: *          = 0:  A * X = B  (No transpose)
029: *          = 1:  A'* X = B  (Transpose)
030: *          = 2:  A'* X = B  (Conjugate transpose = Transpose)
031: *
032: *  N       (input) INTEGER
033: *          The order of the matrix A.
034: *
035: *  NRHS    (input) INTEGER
036: *          The number of right hand sides, i.e., the number of columns
037: *          of the matrix B.  NRHS >= 0.
038: *
039: *  DL      (input) REAL array, dimension (N-1)
040: *          The (n-1) multipliers that define the matrix L from the
041: *          LU factorization of A.
042: *
043: *  D       (input) REAL array, dimension (N)
044: *          The n diagonal elements of the upper triangular matrix U from
045: *          the LU factorization of A.
046: *
047: *  DU      (input) REAL array, dimension (N-1)
048: *          The (n-1) elements of the first super-diagonal of U.
049: *
050: *  DU2     (input) REAL array, dimension (N-2)
051: *          The (n-2) elements of the second super-diagonal of U.
052: *
053: *  IPIV    (input) INTEGER array, dimension (N)
054: *          The pivot indices; for 1 <= i <= n, row i of the matrix was
055: *          interchanged with row IPIV(i).  IPIV(i) will always be either
056: *          i or i+1; IPIV(i) = i indicates a row interchange was not
057: *          required.
058: *
059: *  B       (input/output) REAL array, dimension (LDB,NRHS)
060: *          On entry, the matrix of right hand side vectors B.
061: *          On exit, B is overwritten by the solution vectors X.
062: *
063: *  LDB     (input) INTEGER
064: *          The leading dimension of the array B.  LDB >= max(1,N).
065: *
066: *  =====================================================================
067: *
068: *     .. Local Scalars ..
069:       INTEGER            I, IP, J
070:       REAL               TEMP
071: *     ..
072: *     .. Executable Statements ..
073: *
074: *     Quick return if possible
075: *
076:       IF( N.EQ.0 .OR. NRHS.EQ.0 )
077:      $   RETURN
078: *
079:       IF( ITRANS.EQ.0 ) THEN
080: *
081: *        Solve A*X = B using the LU factorization of A,
082: *        overwriting each right hand side vector with its solution.
083: *
084:          IF( NRHS.LE.1 ) THEN
085:             J = 1
086:    10       CONTINUE
087: *
088: *           Solve L*x = b.
089: *
090:             DO 20 I = 1, N - 1
091:                IP = IPIV( I )
092:                TEMP = B( I+1-IP+I, J ) - DL( I )*B( IP, J )
093:                B( I, J ) = B( IP, J )
094:                B( I+1, J ) = TEMP
095:    20       CONTINUE
096: *
097: *           Solve U*x = b.
098: *
099:             B( N, J ) = B( N, J ) / D( N )
100:             IF( N.GT.1 )
101:      $         B( N-1, J ) = ( B( N-1, J )-DU( N-1 )*B( N, J ) ) /
102:      $                       D( N-1 )
103:             DO 30 I = N - 2, 1, -1
104:                B( I, J ) = ( B( I, J )-DU( I )*B( I+1, J )-DU2( I )*
105:      $                     B( I+2, J ) ) / D( I )
106:    30       CONTINUE
107:             IF( J.LT.NRHS ) THEN
108:                J = J + 1
109:                GO TO 10
110:             END IF
111:          ELSE
112:             DO 60 J = 1, NRHS
113: *
114: *              Solve L*x = b.
115: *
116:                DO 40 I = 1, N - 1
117:                   IF( IPIV( I ).EQ.I ) THEN
118:                      B( I+1, J ) = B( I+1, J ) - DL( I )*B( I, J )
119:                   ELSE
120:                      TEMP = B( I, J )
121:                      B( I, J ) = B( I+1, J )
122:                      B( I+1, J ) = TEMP - DL( I )*B( I, J )
123:                   END IF
124:    40          CONTINUE
125: *
126: *              Solve U*x = b.
127: *
128:                B( N, J ) = B( N, J ) / D( N )
129:                IF( N.GT.1 )
130:      $            B( N-1, J ) = ( B( N-1, J )-DU( N-1 )*B( N, J ) ) /
131:      $                          D( N-1 )
132:                DO 50 I = N - 2, 1, -1
133:                   B( I, J ) = ( B( I, J )-DU( I )*B( I+1, J )-DU2( I )*
134:      $                        B( I+2, J ) ) / D( I )
135:    50          CONTINUE
136:    60       CONTINUE
137:          END IF
138:       ELSE
139: *
140: *        Solve A' * X = B.
141: *
142:          IF( NRHS.LE.1 ) THEN
143: *
144: *           Solve U'*x = b.
145: *
146:             J = 1
147:    70       CONTINUE
148:             B( 1, J ) = B( 1, J ) / D( 1 )
149:             IF( N.GT.1 )
150:      $         B( 2, J ) = ( B( 2, J )-DU( 1 )*B( 1, J ) ) / D( 2 )
151:             DO 80 I = 3, N
152:                B( I, J ) = ( B( I, J )-DU( I-1 )*B( I-1, J )-DU2( I-2 )*
153:      $                     B( I-2, J ) ) / D( I )
154:    80       CONTINUE
155: *
156: *           Solve L'*x = b.
157: *
158:             DO 90 I = N - 1, 1, -1
159:                IP = IPIV( I )
160:                TEMP = B( I, J ) - DL( I )*B( I+1, J )
161:                B( I, J ) = B( IP, J )
162:                B( IP, J ) = TEMP
163:    90       CONTINUE
164:             IF( J.LT.NRHS ) THEN
165:                J = J + 1
166:                GO TO 70
167:             END IF
168: *
169:          ELSE
170:             DO 120 J = 1, NRHS
171: *
172: *              Solve U'*x = b.
173: *
174:                B( 1, J ) = B( 1, J ) / D( 1 )
175:                IF( N.GT.1 )
176:      $            B( 2, J ) = ( B( 2, J )-DU( 1 )*B( 1, J ) ) / D( 2 )
177:                DO 100 I = 3, N
178:                   B( I, J ) = ( B( I, J )-DU( I-1 )*B( I-1, J )-
179:      $                        DU2( I-2 )*B( I-2, J ) ) / D( I )
180:   100          CONTINUE
181:                DO 110 I = N - 1, 1, -1
182:                   IF( IPIV( I ).EQ.I ) THEN
183:                      B( I, J ) = B( I, J ) - DL( I )*B( I+1, J )
184:                   ELSE
185:                      TEMP = B( I+1, J )
186:                      B( I+1, J ) = B( I, J ) - DL( I )*TEMP
187:                      B( I, J ) = TEMP
188:                   END IF
189:   110          CONTINUE
190:   120       CONTINUE
191:          END IF
192:       END IF
193: *
194: *     End of SGTTS2
195: *
196:       END
197: