001:       SUBROUTINE SGECON( NORM, N, A, LDA, ANORM, RCOND, WORK, IWORK,
002:      $                   INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     Modified to call SLACN2 in place of SLACON, 7 Feb 03, SJH.
009: *
010: *     .. Scalar Arguments ..
011:       CHARACTER          NORM
012:       INTEGER            INFO, LDA, N
013:       REAL               ANORM, RCOND
014: *     ..
015: *     .. Array Arguments ..
016:       INTEGER            IWORK( * )
017:       REAL               A( LDA, * ), WORK( * )
018: *     ..
019: *
020: *  Purpose
021: *  =======
022: *
023: *  SGECON estimates the reciprocal of the condition number of a general
024: *  real matrix A, in either the 1-norm or the infinity-norm, using
025: *  the LU factorization computed by SGETRF.
026: *
027: *  An estimate is obtained for norm(inv(A)), and the reciprocal of the
028: *  condition number is computed as
029: *     RCOND = 1 / ( norm(A) * norm(inv(A)) ).
030: *
031: *  Arguments
032: *  =========
033: *
034: *  NORM    (input) CHARACTER*1
035: *          Specifies whether the 1-norm condition number or the
036: *          infinity-norm condition number is required:
037: *          = '1' or 'O':  1-norm;
038: *          = 'I':         Infinity-norm.
039: *
040: *  N       (input) INTEGER
041: *          The order of the matrix A.  N >= 0.
042: *
043: *  A       (input) REAL array, dimension (LDA,N)
044: *          The factors L and U from the factorization A = P*L*U
045: *          as computed by SGETRF.
046: *
047: *  LDA     (input) INTEGER
048: *          The leading dimension of the array A.  LDA >= max(1,N).
049: *
050: *  ANORM   (input) REAL
051: *          If NORM = '1' or 'O', the 1-norm of the original matrix A.
052: *          If NORM = 'I', the infinity-norm of the original matrix A.
053: *
054: *  RCOND   (output) REAL
055: *          The reciprocal of the condition number of the matrix A,
056: *          computed as RCOND = 1/(norm(A) * norm(inv(A))).
057: *
058: *  WORK    (workspace) REAL array, dimension (4*N)
059: *
060: *  IWORK   (workspace) INTEGER array, dimension (N)
061: *
062: *  INFO    (output) INTEGER
063: *          = 0:  successful exit
064: *          < 0:  if INFO = -i, the i-th argument had an illegal value
065: *
066: *  =====================================================================
067: *
068: *     .. Parameters ..
069:       REAL               ONE, ZERO
070:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
071: *     ..
072: *     .. Local Scalars ..
073:       LOGICAL            ONENRM
074:       CHARACTER          NORMIN
075:       INTEGER            IX, KASE, KASE1
076:       REAL               AINVNM, SCALE, SL, SMLNUM, SU
077: *     ..
078: *     .. Local Arrays ..
079:       INTEGER            ISAVE( 3 )
080: *     ..
081: *     .. External Functions ..
082:       LOGICAL            LSAME
083:       INTEGER            ISAMAX
084:       REAL               SLAMCH
085:       EXTERNAL           LSAME, ISAMAX, SLAMCH
086: *     ..
087: *     .. External Subroutines ..
088:       EXTERNAL           SLACN2, SLATRS, SRSCL, XERBLA
089: *     ..
090: *     .. Intrinsic Functions ..
091:       INTRINSIC          ABS, MAX
092: *     ..
093: *     .. Executable Statements ..
094: *
095: *     Test the input parameters.
096: *
097:       INFO = 0
098:       ONENRM = NORM.EQ.'1' .OR. LSAME( NORM, 'O' )
099:       IF( .NOT.ONENRM .AND. .NOT.LSAME( NORM, 'I' ) ) THEN
100:          INFO = -1
101:       ELSE IF( N.LT.0 ) THEN
102:          INFO = -2
103:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
104:          INFO = -4
105:       ELSE IF( ANORM.LT.ZERO ) THEN
106:          INFO = -5
107:       END IF
108:       IF( INFO.NE.0 ) THEN
109:          CALL XERBLA( 'SGECON', -INFO )
110:          RETURN
111:       END IF
112: *
113: *     Quick return if possible
114: *
115:       RCOND = ZERO
116:       IF( N.EQ.0 ) THEN
117:          RCOND = ONE
118:          RETURN
119:       ELSE IF( ANORM.EQ.ZERO ) THEN
120:          RETURN
121:       END IF
122: *
123:       SMLNUM = SLAMCH( 'Safe minimum' )
124: *
125: *     Estimate the norm of inv(A).
126: *
127:       AINVNM = ZERO
128:       NORMIN = 'N'
129:       IF( ONENRM ) THEN
130:          KASE1 = 1
131:       ELSE
132:          KASE1 = 2
133:       END IF
134:       KASE = 0
135:    10 CONTINUE
136:       CALL SLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
137:       IF( KASE.NE.0 ) THEN
138:          IF( KASE.EQ.KASE1 ) THEN
139: *
140: *           Multiply by inv(L).
141: *
142:             CALL SLATRS( 'Lower', 'No transpose', 'Unit', NORMIN, N, A,
143:      $                   LDA, WORK, SL, WORK( 2*N+1 ), INFO )
144: *
145: *           Multiply by inv(U).
146: *
147:             CALL SLATRS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
148:      $                   A, LDA, WORK, SU, WORK( 3*N+1 ), INFO )
149:          ELSE
150: *
151: *           Multiply by inv(U').
152: *
153:             CALL SLATRS( 'Upper', 'Transpose', 'Non-unit', NORMIN, N, A,
154:      $                   LDA, WORK, SU, WORK( 3*N+1 ), INFO )
155: *
156: *           Multiply by inv(L').
157: *
158:             CALL SLATRS( 'Lower', 'Transpose', 'Unit', NORMIN, N, A,
159:      $                   LDA, WORK, SL, WORK( 2*N+1 ), INFO )
160:          END IF
161: *
162: *        Divide X by 1/(SL*SU) if doing so will not cause overflow.
163: *
164:          SCALE = SL*SU
165:          NORMIN = 'Y'
166:          IF( SCALE.NE.ONE ) THEN
167:             IX = ISAMAX( N, WORK, 1 )
168:             IF( SCALE.LT.ABS( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
169:      $         GO TO 20
170:             CALL SRSCL( N, SCALE, WORK, 1 )
171:          END IF
172:          GO TO 10
173:       END IF
174: *
175: *     Compute the estimate of the reciprocal condition number.
176: *
177:       IF( AINVNM.NE.ZERO )
178:      $   RCOND = ( ONE / AINVNM ) / ANORM
179: *
180:    20 CONTINUE
181:       RETURN
182: *
183: *     End of SGECON
184: *
185:       END
186: