001:       SUBROUTINE DPOTRF( UPLO, N, A, LDA, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          UPLO
009:       INTEGER            INFO, LDA, N
010: *     ..
011: *     .. Array Arguments ..
012:       DOUBLE PRECISION   A( LDA, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  DPOTRF computes the Cholesky factorization of a real symmetric
019: *  positive definite matrix A.
020: *
021: *  The factorization has the form
022: *     A = U**T * U,  if UPLO = 'U', or
023: *     A = L  * L**T,  if UPLO = 'L',
024: *  where U is an upper triangular matrix and L is lower triangular.
025: *
026: *  This is the block version of the algorithm, calling Level 3 BLAS.
027: *
028: *  Arguments
029: *  =========
030: *
031: *  UPLO    (input) CHARACTER*1
032: *          = 'U':  Upper triangle of A is stored;
033: *          = 'L':  Lower triangle of A is stored.
034: *
035: *  N       (input) INTEGER
036: *          The order of the matrix A.  N >= 0.
037: *
038: *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
039: *          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
040: *          N-by-N upper triangular part of A contains the upper
041: *          triangular part of the matrix A, and the strictly lower
042: *          triangular part of A is not referenced.  If UPLO = 'L', the
043: *          leading N-by-N lower triangular part of A contains the lower
044: *          triangular part of the matrix A, and the strictly upper
045: *          triangular part of A is not referenced.
046: *
047: *          On exit, if INFO = 0, the factor U or L from the Cholesky
048: *          factorization A = U**T*U or A = L*L**T.
049: *
050: *  LDA     (input) INTEGER
051: *          The leading dimension of the array A.  LDA >= max(1,N).
052: *
053: *  INFO    (output) INTEGER
054: *          = 0:  successful exit
055: *          < 0:  if INFO = -i, the i-th argument had an illegal value
056: *          > 0:  if INFO = i, the leading minor of order i is not
057: *                positive definite, and the factorization could not be
058: *                completed.
059: *
060: *  =====================================================================
061: *
062: *     .. Parameters ..
063:       DOUBLE PRECISION   ONE
064:       PARAMETER          ( ONE = 1.0D+0 )
065: *     ..
066: *     .. Local Scalars ..
067:       LOGICAL            UPPER
068:       INTEGER            J, JB, NB
069: *     ..
070: *     .. External Functions ..
071:       LOGICAL            LSAME
072:       INTEGER            ILAENV
073:       EXTERNAL           LSAME, ILAENV
074: *     ..
075: *     .. External Subroutines ..
076:       EXTERNAL           DGEMM, DPOTF2, DSYRK, DTRSM, XERBLA
077: *     ..
078: *     .. Intrinsic Functions ..
079:       INTRINSIC          MAX, MIN
080: *     ..
081: *     .. Executable Statements ..
082: *
083: *     Test the input parameters.
084: *
085:       INFO = 0
086:       UPPER = LSAME( UPLO, 'U' )
087:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
088:          INFO = -1
089:       ELSE IF( N.LT.0 ) THEN
090:          INFO = -2
091:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
092:          INFO = -4
093:       END IF
094:       IF( INFO.NE.0 ) THEN
095:          CALL XERBLA( 'DPOTRF', -INFO )
096:          RETURN
097:       END IF
098: *
099: *     Quick return if possible
100: *
101:       IF( N.EQ.0 )
102:      $   RETURN
103: *
104: *     Determine the block size for this environment.
105: *
106:       NB = ILAENV( 1, 'DPOTRF', UPLO, N, -1, -1, -1 )
107:       IF( NB.LE.1 .OR. NB.GE.N ) THEN
108: *
109: *        Use unblocked code.
110: *
111:          CALL DPOTF2( UPLO, N, A, LDA, INFO )
112:       ELSE
113: *
114: *        Use blocked code.
115: *
116:          IF( UPPER ) THEN
117: *
118: *           Compute the Cholesky factorization A = U'*U.
119: *
120:             DO 10 J = 1, N, NB
121: *
122: *              Update and factorize the current diagonal block and test
123: *              for non-positive-definiteness.
124: *
125:                JB = MIN( NB, N-J+1 )
126:                CALL DSYRK( 'Upper', 'Transpose', JB, J-1, -ONE,
127:      $                     A( 1, J ), LDA, ONE, A( J, J ), LDA )
128:                CALL DPOTF2( 'Upper', JB, A( J, J ), LDA, INFO )
129:                IF( INFO.NE.0 )
130:      $            GO TO 30
131:                IF( J+JB.LE.N ) THEN
132: *
133: *                 Compute the current block row.
134: *
135:                   CALL DGEMM( 'Transpose', 'No transpose', JB, N-J-JB+1,
136:      $                        J-1, -ONE, A( 1, J ), LDA, A( 1, J+JB ),
137:      $                        LDA, ONE, A( J, J+JB ), LDA )
138:                   CALL DTRSM( 'Left', 'Upper', 'Transpose', 'Non-unit',
139:      $                        JB, N-J-JB+1, ONE, A( J, J ), LDA,
140:      $                        A( J, J+JB ), LDA )
141:                END IF
142:    10       CONTINUE
143: *
144:          ELSE
145: *
146: *           Compute the Cholesky factorization A = L*L'.
147: *
148:             DO 20 J = 1, N, NB
149: *
150: *              Update and factorize the current diagonal block and test
151: *              for non-positive-definiteness.
152: *
153:                JB = MIN( NB, N-J+1 )
154:                CALL DSYRK( 'Lower', 'No transpose', JB, J-1, -ONE,
155:      $                     A( J, 1 ), LDA, ONE, A( J, J ), LDA )
156:                CALL DPOTF2( 'Lower', JB, A( J, J ), LDA, INFO )
157:                IF( INFO.NE.0 )
158:      $            GO TO 30
159:                IF( J+JB.LE.N ) THEN
160: *
161: *                 Compute the current block column.
162: *
163:                   CALL DGEMM( 'No transpose', 'Transpose', N-J-JB+1, JB,
164:      $                        J-1, -ONE, A( J+JB, 1 ), LDA, A( J, 1 ),
165:      $                        LDA, ONE, A( J+JB, J ), LDA )
166:                   CALL DTRSM( 'Right', 'Lower', 'Transpose', 'Non-unit',
167:      $                        N-J-JB+1, JB, ONE, A( J, J ), LDA,
168:      $                        A( J+JB, J ), LDA )
169:                END IF
170:    20       CONTINUE
171:          END IF
172:       END IF
173:       GO TO 40
174: *
175:    30 CONTINUE
176:       INFO = INFO + J - 1
177: *
178:    40 CONTINUE
179:       RETURN
180: *
181: *     End of DPOTRF
182: *
183:       END
184: