001:       SUBROUTINE DPBCON( UPLO, N, KD, AB, LDAB, ANORM, RCOND, WORK,
002:      $                   IWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     Modified to call DLACN2 in place of DLACON, 5 Feb 03, SJH.
009: *
010: *     .. Scalar Arguments ..
011:       CHARACTER          UPLO
012:       INTEGER            INFO, KD, LDAB, N
013:       DOUBLE PRECISION   ANORM, RCOND
014: *     ..
015: *     .. Array Arguments ..
016:       INTEGER            IWORK( * )
017:       DOUBLE PRECISION   AB( LDAB, * ), WORK( * )
018: *     ..
019: *
020: *  Purpose
021: *  =======
022: *
023: *  DPBCON estimates the reciprocal of the condition number (in the
024: *  1-norm) of a real symmetric positive definite band matrix using the
025: *  Cholesky factorization A = U**T*U or A = L*L**T computed by DPBTRF.
026: *
027: *  An estimate is obtained for norm(inv(A)), and the reciprocal of the
028: *  condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
029: *
030: *  Arguments
031: *  =========
032: *
033: *  UPLO    (input) CHARACTER*1
034: *          = 'U':  Upper triangular factor stored in AB;
035: *          = 'L':  Lower triangular factor stored in AB.
036: *
037: *  N       (input) INTEGER
038: *          The order of the matrix A.  N >= 0.
039: *
040: *  KD      (input) INTEGER
041: *          The number of superdiagonals of the matrix A if UPLO = 'U',
042: *          or the number of subdiagonals if UPLO = 'L'.  KD >= 0.
043: *
044: *  AB      (input) DOUBLE PRECISION array, dimension (LDAB,N)
045: *          The triangular factor U or L from the Cholesky factorization
046: *          A = U**T*U or A = L*L**T of the band matrix A, stored in the
047: *          first KD+1 rows of the array.  The j-th column of U or L is
048: *          stored in the j-th column of the array AB as follows:
049: *          if UPLO ='U', AB(kd+1+i-j,j) = U(i,j) for max(1,j-kd)<=i<=j;
050: *          if UPLO ='L', AB(1+i-j,j)    = L(i,j) for j<=i<=min(n,j+kd).
051: *
052: *  LDAB    (input) INTEGER
053: *          The leading dimension of the array AB.  LDAB >= KD+1.
054: *
055: *  ANORM   (input) DOUBLE PRECISION
056: *          The 1-norm (or infinity-norm) of the symmetric band matrix A.
057: *
058: *  RCOND   (output) DOUBLE PRECISION
059: *          The reciprocal of the condition number of the matrix A,
060: *          computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
061: *          estimate of the 1-norm of inv(A) computed in this routine.
062: *
063: *  WORK    (workspace) DOUBLE PRECISION array, dimension (3*N)
064: *
065: *  IWORK   (workspace) INTEGER array, dimension (N)
066: *
067: *  INFO    (output) INTEGER
068: *          = 0:  successful exit
069: *          < 0:  if INFO = -i, the i-th argument had an illegal value
070: *
071: *  =====================================================================
072: *
073: *     .. Parameters ..
074:       DOUBLE PRECISION   ONE, ZERO
075:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
076: *     ..
077: *     .. Local Scalars ..
078:       LOGICAL            UPPER
079:       CHARACTER          NORMIN
080:       INTEGER            IX, KASE
081:       DOUBLE PRECISION   AINVNM, SCALE, SCALEL, SCALEU, SMLNUM
082: *     ..
083: *     .. Local Arrays ..
084:       INTEGER            ISAVE( 3 )
085: *     ..
086: *     .. External Functions ..
087:       LOGICAL            LSAME
088:       INTEGER            IDAMAX
089:       DOUBLE PRECISION   DLAMCH
090:       EXTERNAL           LSAME, IDAMAX, DLAMCH
091: *     ..
092: *     .. External Subroutines ..
093:       EXTERNAL           DLACN2, DLATBS, DRSCL, XERBLA
094: *     ..
095: *     .. Intrinsic Functions ..
096:       INTRINSIC          ABS
097: *     ..
098: *     .. Executable Statements ..
099: *
100: *     Test the input parameters.
101: *
102:       INFO = 0
103:       UPPER = LSAME( UPLO, 'U' )
104:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
105:          INFO = -1
106:       ELSE IF( N.LT.0 ) THEN
107:          INFO = -2
108:       ELSE IF( KD.LT.0 ) THEN
109:          INFO = -3
110:       ELSE IF( LDAB.LT.KD+1 ) THEN
111:          INFO = -5
112:       ELSE IF( ANORM.LT.ZERO ) THEN
113:          INFO = -6
114:       END IF
115:       IF( INFO.NE.0 ) THEN
116:          CALL XERBLA( 'DPBCON', -INFO )
117:          RETURN
118:       END IF
119: *
120: *     Quick return if possible
121: *
122:       RCOND = ZERO
123:       IF( N.EQ.0 ) THEN
124:          RCOND = ONE
125:          RETURN
126:       ELSE IF( ANORM.EQ.ZERO ) THEN
127:          RETURN
128:       END IF
129: *
130:       SMLNUM = DLAMCH( 'Safe minimum' )
131: *
132: *     Estimate the 1-norm of the inverse.
133: *
134:       KASE = 0
135:       NORMIN = 'N'
136:    10 CONTINUE
137:       CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
138:       IF( KASE.NE.0 ) THEN
139:          IF( UPPER ) THEN
140: *
141: *           Multiply by inv(U').
142: *
143:             CALL DLATBS( 'Upper', 'Transpose', 'Non-unit', NORMIN, N,
144:      $                   KD, AB, LDAB, WORK, SCALEL, WORK( 2*N+1 ),
145:      $                   INFO )
146:             NORMIN = 'Y'
147: *
148: *           Multiply by inv(U).
149: *
150:             CALL DLATBS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
151:      $                   KD, AB, LDAB, WORK, SCALEU, WORK( 2*N+1 ),
152:      $                   INFO )
153:          ELSE
154: *
155: *           Multiply by inv(L).
156: *
157:             CALL DLATBS( 'Lower', 'No transpose', 'Non-unit', NORMIN, N,
158:      $                   KD, AB, LDAB, WORK, SCALEL, WORK( 2*N+1 ),
159:      $                   INFO )
160:             NORMIN = 'Y'
161: *
162: *           Multiply by inv(L').
163: *
164:             CALL DLATBS( 'Lower', 'Transpose', 'Non-unit', NORMIN, N,
165:      $                   KD, AB, LDAB, WORK, SCALEU, WORK( 2*N+1 ),
166:      $                   INFO )
167:          END IF
168: *
169: *        Multiply by 1/SCALE if doing so will not cause overflow.
170: *
171:          SCALE = SCALEL*SCALEU
172:          IF( SCALE.NE.ONE ) THEN
173:             IX = IDAMAX( N, WORK, 1 )
174:             IF( SCALE.LT.ABS( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
175:      $         GO TO 20
176:             CALL DRSCL( N, SCALE, WORK, 1 )
177:          END IF
178:          GO TO 10
179:       END IF
180: *
181: *     Compute the estimate of the reciprocal condition number.
182: *
183:       IF( AINVNM.NE.ZERO )
184:      $   RCOND = ( ONE / AINVNM ) / ANORM
185: *
186:    20 CONTINUE
187: *
188:       RETURN
189: *
190: *     End of DPBCON
191: *
192:       END
193: