001:       SUBROUTINE DORMQL( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  DORMQL overwrites the general real M-by-N matrix C with
020: *
021: *                  SIDE = 'L'     SIDE = 'R'
022: *  TRANS = 'N':      Q * C          C * Q
023: *  TRANS = 'T':      Q**T * C       C * Q**T
024: *
025: *  where Q is a real orthogonal matrix defined as the product of k
026: *  elementary reflectors
027: *
028: *        Q = H(k) . . . H(2) H(1)
029: *
030: *  as returned by DGEQLF. Q is of order M if SIDE = 'L' and of order N
031: *  if SIDE = 'R'.
032: *
033: *  Arguments
034: *  =========
035: *
036: *  SIDE    (input) CHARACTER*1
037: *          = 'L': apply Q or Q**T from the Left;
038: *          = 'R': apply Q or Q**T from the Right.
039: *
040: *  TRANS   (input) CHARACTER*1
041: *          = 'N':  No transpose, apply Q;
042: *          = 'T':  Transpose, apply Q**T.
043: *
044: *  M       (input) INTEGER
045: *          The number of rows of the matrix C. M >= 0.
046: *
047: *  N       (input) INTEGER
048: *          The number of columns of the matrix C. N >= 0.
049: *
050: *  K       (input) INTEGER
051: *          The number of elementary reflectors whose product defines
052: *          the matrix Q.
053: *          If SIDE = 'L', M >= K >= 0;
054: *          if SIDE = 'R', N >= K >= 0.
055: *
056: *  A       (input) DOUBLE PRECISION array, dimension (LDA,K)
057: *          The i-th column must contain the vector which defines the
058: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
059: *          DGEQLF in the last k columns of its array argument A.
060: *          A is modified by the routine but restored on exit.
061: *
062: *  LDA     (input) INTEGER
063: *          The leading dimension of the array A.
064: *          If SIDE = 'L', LDA >= max(1,M);
065: *          if SIDE = 'R', LDA >= max(1,N).
066: *
067: *  TAU     (input) DOUBLE PRECISION array, dimension (K)
068: *          TAU(i) must contain the scalar factor of the elementary
069: *          reflector H(i), as returned by DGEQLF.
070: *
071: *  C       (input/output) DOUBLE PRECISION array, dimension (LDC,N)
072: *          On entry, the M-by-N matrix C.
073: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
074: *
075: *  LDC     (input) INTEGER
076: *          The leading dimension of the array C. LDC >= max(1,M).
077: *
078: *  WORK    (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
079: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
080: *
081: *  LWORK   (input) INTEGER
082: *          The dimension of the array WORK.
083: *          If SIDE = 'L', LWORK >= max(1,N);
084: *          if SIDE = 'R', LWORK >= max(1,M).
085: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
086: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
087: *          blocksize.
088: *
089: *          If LWORK = -1, then a workspace query is assumed; the routine
090: *          only calculates the optimal size of the WORK array, returns
091: *          this value as the first entry of the WORK array, and no error
092: *          message related to LWORK is issued by XERBLA.
093: *
094: *  INFO    (output) INTEGER
095: *          = 0:  successful exit
096: *          < 0:  if INFO = -i, the i-th argument had an illegal value
097: *
098: *  =====================================================================
099: *
100: *     .. Parameters ..
101:       INTEGER            NBMAX, LDT
102:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
103: *     ..
104: *     .. Local Scalars ..
105:       LOGICAL            LEFT, LQUERY, NOTRAN
106:       INTEGER            I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
107:      $                   MI, NB, NBMIN, NI, NQ, NW
108: *     ..
109: *     .. Local Arrays ..
110:       DOUBLE PRECISION   T( LDT, NBMAX )
111: *     ..
112: *     .. External Functions ..
113:       LOGICAL            LSAME
114:       INTEGER            ILAENV
115:       EXTERNAL           LSAME, ILAENV
116: *     ..
117: *     .. External Subroutines ..
118:       EXTERNAL           DLARFB, DLARFT, DORM2L, XERBLA
119: *     ..
120: *     .. Intrinsic Functions ..
121:       INTRINSIC          MAX, MIN
122: *     ..
123: *     .. Executable Statements ..
124: *
125: *     Test the input arguments
126: *
127:       INFO = 0
128:       LEFT = LSAME( SIDE, 'L' )
129:       NOTRAN = LSAME( TRANS, 'N' )
130:       LQUERY = ( LWORK.EQ.-1 )
131: *
132: *     NQ is the order of Q and NW is the minimum dimension of WORK
133: *
134:       IF( LEFT ) THEN
135:          NQ = M
136:          NW = MAX( 1, N )
137:       ELSE
138:          NQ = N
139:          NW = MAX( 1, M )
140:       END IF
141:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
142:          INFO = -1
143:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
144:          INFO = -2
145:       ELSE IF( M.LT.0 ) THEN
146:          INFO = -3
147:       ELSE IF( N.LT.0 ) THEN
148:          INFO = -4
149:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
150:          INFO = -5
151:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
152:          INFO = -7
153:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
154:          INFO = -10
155:       END IF
156: *
157:       IF( INFO.EQ.0 ) THEN
158:          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
159:             LWKOPT = 1
160:          ELSE
161: *
162: *           Determine the block size.  NB may be at most NBMAX, where
163: *           NBMAX is used to define the local array T.
164: *
165:             NB = MIN( NBMAX, ILAENV( 1, 'DORMQL', SIDE // TRANS, M, N,
166:      $                               K, -1 ) )
167:             LWKOPT = NW*NB
168:          END IF
169:          WORK( 1 ) = LWKOPT
170: *
171:          IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
172:             INFO = -12
173:          END IF
174:       END IF
175: *
176:       IF( INFO.NE.0 ) THEN
177:          CALL XERBLA( 'DORMQL', -INFO )
178:          RETURN
179:       ELSE IF( LQUERY ) THEN
180:          RETURN
181:       END IF
182: *
183: *     Quick return if possible
184: *
185:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
186:          RETURN
187:       END IF
188: *
189:       NBMIN = 2
190:       LDWORK = NW
191:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
192:          IWS = NW*NB
193:          IF( LWORK.LT.IWS ) THEN
194:             NB = LWORK / LDWORK
195:             NBMIN = MAX( 2, ILAENV( 2, 'DORMQL', SIDE // TRANS, M, N, K,
196:      $              -1 ) )
197:          END IF
198:       ELSE
199:          IWS = NW
200:       END IF
201: *
202:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
203: *
204: *        Use unblocked code
205: *
206:          CALL DORM2L( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
207:      $                IINFO )
208:       ELSE
209: *
210: *        Use blocked code
211: *
212:          IF( ( LEFT .AND. NOTRAN ) .OR.
213:      $       ( .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
214:             I1 = 1
215:             I2 = K
216:             I3 = NB
217:          ELSE
218:             I1 = ( ( K-1 ) / NB )*NB + 1
219:             I2 = 1
220:             I3 = -NB
221:          END IF
222: *
223:          IF( LEFT ) THEN
224:             NI = N
225:          ELSE
226:             MI = M
227:          END IF
228: *
229:          DO 10 I = I1, I2, I3
230:             IB = MIN( NB, K-I+1 )
231: *
232: *           Form the triangular factor of the block reflector
233: *           H = H(i+ib-1) . . . H(i+1) H(i)
234: *
235:             CALL DLARFT( 'Backward', 'Columnwise', NQ-K+I+IB-1, IB,
236:      $                   A( 1, I ), LDA, TAU( I ), T, LDT )
237:             IF( LEFT ) THEN
238: *
239: *              H or H' is applied to C(1:m-k+i+ib-1,1:n)
240: *
241:                MI = M - K + I + IB - 1
242:             ELSE
243: *
244: *              H or H' is applied to C(1:m,1:n-k+i+ib-1)
245: *
246:                NI = N - K + I + IB - 1
247:             END IF
248: *
249: *           Apply H or H'
250: *
251:             CALL DLARFB( SIDE, TRANS, 'Backward', 'Columnwise', MI, NI,
252:      $                   IB, A( 1, I ), LDA, T, LDT, C, LDC, WORK,
253:      $                   LDWORK )
254:    10    CONTINUE
255:       END IF
256:       WORK( 1 ) = LWKOPT
257:       RETURN
258: *
259: *     End of DORMQL
260: *
261:       END
262: