001:       SUBROUTINE DLARZB( SIDE, TRANS, DIRECT, STOREV, M, N, K, L, V,
002:      $                   LDV, T, LDT, C, LDC, WORK, LDWORK )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          DIRECT, SIDE, STOREV, TRANS
010:       INTEGER            K, L, LDC, LDT, LDV, LDWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   C( LDC, * ), T( LDT, * ), V( LDV, * ),
014:      $                   WORK( LDWORK, * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  DLARZB applies a real block reflector H or its transpose H**T to
021: *  a real distributed M-by-N  C from the left or the right.
022: *
023: *  Currently, only STOREV = 'R' and DIRECT = 'B' are supported.
024: *
025: *  Arguments
026: *  =========
027: *
028: *  SIDE    (input) CHARACTER*1
029: *          = 'L': apply H or H' from the Left
030: *          = 'R': apply H or H' from the Right
031: *
032: *  TRANS   (input) CHARACTER*1
033: *          = 'N': apply H (No transpose)
034: *          = 'C': apply H' (Transpose)
035: *
036: *  DIRECT  (input) CHARACTER*1
037: *          Indicates how H is formed from a product of elementary
038: *          reflectors
039: *          = 'F': H = H(1) H(2) . . . H(k) (Forward, not supported yet)
040: *          = 'B': H = H(k) . . . H(2) H(1) (Backward)
041: *
042: *  STOREV  (input) CHARACTER*1
043: *          Indicates how the vectors which define the elementary
044: *          reflectors are stored:
045: *          = 'C': Columnwise                        (not supported yet)
046: *          = 'R': Rowwise
047: *
048: *  M       (input) INTEGER
049: *          The number of rows of the matrix C.
050: *
051: *  N       (input) INTEGER
052: *          The number of columns of the matrix C.
053: *
054: *  K       (input) INTEGER
055: *          The order of the matrix T (= the number of elementary
056: *          reflectors whose product defines the block reflector).
057: *
058: *  L       (input) INTEGER
059: *          The number of columns of the matrix V containing the
060: *          meaningful part of the Householder reflectors.
061: *          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
062: *
063: *  V       (input) DOUBLE PRECISION array, dimension (LDV,NV).
064: *          If STOREV = 'C', NV = K; if STOREV = 'R', NV = L.
065: *
066: *  LDV     (input) INTEGER
067: *          The leading dimension of the array V.
068: *          If STOREV = 'C', LDV >= L; if STOREV = 'R', LDV >= K.
069: *
070: *  T       (input) DOUBLE PRECISION array, dimension (LDT,K)
071: *          The triangular K-by-K matrix T in the representation of the
072: *          block reflector.
073: *
074: *  LDT     (input) INTEGER
075: *          The leading dimension of the array T. LDT >= K.
076: *
077: *  C       (input/output) DOUBLE PRECISION array, dimension (LDC,N)
078: *          On entry, the M-by-N matrix C.
079: *          On exit, C is overwritten by H*C or H'*C or C*H or C*H'.
080: *
081: *  LDC     (input) INTEGER
082: *          The leading dimension of the array C. LDC >= max(1,M).
083: *
084: *  WORK    (workspace) DOUBLE PRECISION array, dimension (LDWORK,K)
085: *
086: *  LDWORK  (input) INTEGER
087: *          The leading dimension of the array WORK.
088: *          If SIDE = 'L', LDWORK >= max(1,N);
089: *          if SIDE = 'R', LDWORK >= max(1,M).
090: *
091: *  Further Details
092: *  ===============
093: *
094: *  Based on contributions by
095: *    A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
096: *
097: *  =====================================================================
098: *
099: *     .. Parameters ..
100:       DOUBLE PRECISION   ONE
101:       PARAMETER          ( ONE = 1.0D+0 )
102: *     ..
103: *     .. Local Scalars ..
104:       CHARACTER          TRANST
105:       INTEGER            I, INFO, J
106: *     ..
107: *     .. External Functions ..
108:       LOGICAL            LSAME
109:       EXTERNAL           LSAME
110: *     ..
111: *     .. External Subroutines ..
112:       EXTERNAL           DCOPY, DGEMM, DTRMM, XERBLA
113: *     ..
114: *     .. Executable Statements ..
115: *
116: *     Quick return if possible
117: *
118:       IF( M.LE.0 .OR. N.LE.0 )
119:      $   RETURN
120: *
121: *     Check for currently supported options
122: *
123:       INFO = 0
124:       IF( .NOT.LSAME( DIRECT, 'B' ) ) THEN
125:          INFO = -3
126:       ELSE IF( .NOT.LSAME( STOREV, 'R' ) ) THEN
127:          INFO = -4
128:       END IF
129:       IF( INFO.NE.0 ) THEN
130:          CALL XERBLA( 'DLARZB', -INFO )
131:          RETURN
132:       END IF
133: *
134:       IF( LSAME( TRANS, 'N' ) ) THEN
135:          TRANST = 'T'
136:       ELSE
137:          TRANST = 'N'
138:       END IF
139: *
140:       IF( LSAME( SIDE, 'L' ) ) THEN
141: *
142: *        Form  H * C  or  H' * C
143: *
144: *        W( 1:n, 1:k ) = C( 1:k, 1:n )'
145: *
146:          DO 10 J = 1, K
147:             CALL DCOPY( N, C( J, 1 ), LDC, WORK( 1, J ), 1 )
148:    10    CONTINUE
149: *
150: *        W( 1:n, 1:k ) = W( 1:n, 1:k ) + ...
151: *                        C( m-l+1:m, 1:n )' * V( 1:k, 1:l )'
152: *
153:          IF( L.GT.0 )
154:      $      CALL DGEMM( 'Transpose', 'Transpose', N, K, L, ONE,
155:      $                  C( M-L+1, 1 ), LDC, V, LDV, ONE, WORK, LDWORK )
156: *
157: *        W( 1:n, 1:k ) = W( 1:n, 1:k ) * T'  or  W( 1:m, 1:k ) * T
158: *
159:          CALL DTRMM( 'Right', 'Lower', TRANST, 'Non-unit', N, K, ONE, T,
160:      $               LDT, WORK, LDWORK )
161: *
162: *        C( 1:k, 1:n ) = C( 1:k, 1:n ) - W( 1:n, 1:k )'
163: *
164:          DO 30 J = 1, N
165:             DO 20 I = 1, K
166:                C( I, J ) = C( I, J ) - WORK( J, I )
167:    20       CONTINUE
168:    30    CONTINUE
169: *
170: *        C( m-l+1:m, 1:n ) = C( m-l+1:m, 1:n ) - ...
171: *                            V( 1:k, 1:l )' * W( 1:n, 1:k )'
172: *
173:          IF( L.GT.0 )
174:      $      CALL DGEMM( 'Transpose', 'Transpose', L, N, K, -ONE, V, LDV,
175:      $                  WORK, LDWORK, ONE, C( M-L+1, 1 ), LDC )
176: *
177:       ELSE IF( LSAME( SIDE, 'R' ) ) THEN
178: *
179: *        Form  C * H  or  C * H'
180: *
181: *        W( 1:m, 1:k ) = C( 1:m, 1:k )
182: *
183:          DO 40 J = 1, K
184:             CALL DCOPY( M, C( 1, J ), 1, WORK( 1, J ), 1 )
185:    40    CONTINUE
186: *
187: *        W( 1:m, 1:k ) = W( 1:m, 1:k ) + ...
188: *                        C( 1:m, n-l+1:n ) * V( 1:k, 1:l )'
189: *
190:          IF( L.GT.0 )
191:      $      CALL DGEMM( 'No transpose', 'Transpose', M, K, L, ONE,
192:      $                  C( 1, N-L+1 ), LDC, V, LDV, ONE, WORK, LDWORK )
193: *
194: *        W( 1:m, 1:k ) = W( 1:m, 1:k ) * T  or  W( 1:m, 1:k ) * T'
195: *
196:          CALL DTRMM( 'Right', 'Lower', TRANS, 'Non-unit', M, K, ONE, T,
197:      $               LDT, WORK, LDWORK )
198: *
199: *        C( 1:m, 1:k ) = C( 1:m, 1:k ) - W( 1:m, 1:k )
200: *
201:          DO 60 J = 1, K
202:             DO 50 I = 1, M
203:                C( I, J ) = C( I, J ) - WORK( I, J )
204:    50       CONTINUE
205:    60    CONTINUE
206: *
207: *        C( 1:m, n-l+1:n ) = C( 1:m, n-l+1:n ) - ...
208: *                            W( 1:m, 1:k ) * V( 1:k, 1:l )
209: *
210:          IF( L.GT.0 )
211:      $      CALL DGEMM( 'No transpose', 'No transpose', M, L, K, -ONE,
212:      $                  WORK, LDWORK, V, LDV, ONE, C( 1, N-L+1 ), LDC )
213: *
214:       END IF
215: *
216:       RETURN
217: *
218: *     End of DLARZB
219: *
220:       END
221: