001:       DOUBLE PRECISION FUNCTION DLANTB( NORM, UPLO, DIAG, N, K, AB,
002:      $                 LDAB, WORK )
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          DIAG, NORM, UPLO
010:       INTEGER            K, LDAB, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   AB( LDAB, * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  DLANTB  returns the value of the one norm,  or the Frobenius norm, or
020: *  the  infinity norm,  or the element of  largest absolute value  of an
021: *  n by n triangular band matrix A,  with ( k + 1 ) diagonals.
022: *
023: *  Description
024: *  ===========
025: *
026: *  DLANTB returns the value
027: *
028: *     DLANTB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
029: *              (
030: *              ( norm1(A),         NORM = '1', 'O' or 'o'
031: *              (
032: *              ( normI(A),         NORM = 'I' or 'i'
033: *              (
034: *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
035: *
036: *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
037: *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
038: *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
039: *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
040: *
041: *  Arguments
042: *  =========
043: *
044: *  NORM    (input) CHARACTER*1
045: *          Specifies the value to be returned in DLANTB as described
046: *          above.
047: *
048: *  UPLO    (input) CHARACTER*1
049: *          Specifies whether the matrix A is upper or lower triangular.
050: *          = 'U':  Upper triangular
051: *          = 'L':  Lower triangular
052: *
053: *  DIAG    (input) CHARACTER*1
054: *          Specifies whether or not the matrix A is unit triangular.
055: *          = 'N':  Non-unit triangular
056: *          = 'U':  Unit triangular
057: *
058: *  N       (input) INTEGER
059: *          The order of the matrix A.  N >= 0.  When N = 0, DLANTB is
060: *          set to zero.
061: *
062: *  K       (input) INTEGER
063: *          The number of super-diagonals of the matrix A if UPLO = 'U',
064: *          or the number of sub-diagonals of the matrix A if UPLO = 'L'.
065: *          K >= 0.
066: *
067: *  AB      (input) DOUBLE PRECISION array, dimension (LDAB,N)
068: *          The upper or lower triangular band matrix A, stored in the
069: *          first k+1 rows of AB.  The j-th column of A is stored
070: *          in the j-th column of the array AB as follows:
071: *          if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
072: *          if UPLO = 'L', AB(1+i-j,j)   = A(i,j) for j<=i<=min(n,j+k).
073: *          Note that when DIAG = 'U', the elements of the array AB
074: *          corresponding to the diagonal elements of the matrix A are
075: *          not referenced, but are assumed to be one.
076: *
077: *  LDAB    (input) INTEGER
078: *          The leading dimension of the array AB.  LDAB >= K+1.
079: *
080: *  WORK    (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
081: *          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
082: *          referenced.
083: *
084: * =====================================================================
085: *
086: *     .. Parameters ..
087:       DOUBLE PRECISION   ONE, ZERO
088:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
089: *     ..
090: *     .. Local Scalars ..
091:       LOGICAL            UDIAG
092:       INTEGER            I, J, L
093:       DOUBLE PRECISION   SCALE, SUM, VALUE
094: *     ..
095: *     .. External Subroutines ..
096:       EXTERNAL           DLASSQ
097: *     ..
098: *     .. External Functions ..
099:       LOGICAL            LSAME
100:       EXTERNAL           LSAME
101: *     ..
102: *     .. Intrinsic Functions ..
103:       INTRINSIC          ABS, MAX, MIN, SQRT
104: *     ..
105: *     .. Executable Statements ..
106: *
107:       IF( N.EQ.0 ) THEN
108:          VALUE = ZERO
109:       ELSE IF( LSAME( NORM, 'M' ) ) THEN
110: *
111: *        Find max(abs(A(i,j))).
112: *
113:          IF( LSAME( DIAG, 'U' ) ) THEN
114:             VALUE = ONE
115:             IF( LSAME( UPLO, 'U' ) ) THEN
116:                DO 20 J = 1, N
117:                   DO 10 I = MAX( K+2-J, 1 ), K
118:                      VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
119:    10             CONTINUE
120:    20          CONTINUE
121:             ELSE
122:                DO 40 J = 1, N
123:                   DO 30 I = 2, MIN( N+1-J, K+1 )
124:                      VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
125:    30             CONTINUE
126:    40          CONTINUE
127:             END IF
128:          ELSE
129:             VALUE = ZERO
130:             IF( LSAME( UPLO, 'U' ) ) THEN
131:                DO 60 J = 1, N
132:                   DO 50 I = MAX( K+2-J, 1 ), K + 1
133:                      VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
134:    50             CONTINUE
135:    60          CONTINUE
136:             ELSE
137:                DO 80 J = 1, N
138:                   DO 70 I = 1, MIN( N+1-J, K+1 )
139:                      VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
140:    70             CONTINUE
141:    80          CONTINUE
142:             END IF
143:          END IF
144:       ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
145: *
146: *        Find norm1(A).
147: *
148:          VALUE = ZERO
149:          UDIAG = LSAME( DIAG, 'U' )
150:          IF( LSAME( UPLO, 'U' ) ) THEN
151:             DO 110 J = 1, N
152:                IF( UDIAG ) THEN
153:                   SUM = ONE
154:                   DO 90 I = MAX( K+2-J, 1 ), K
155:                      SUM = SUM + ABS( AB( I, J ) )
156:    90             CONTINUE
157:                ELSE
158:                   SUM = ZERO
159:                   DO 100 I = MAX( K+2-J, 1 ), K + 1
160:                      SUM = SUM + ABS( AB( I, J ) )
161:   100             CONTINUE
162:                END IF
163:                VALUE = MAX( VALUE, SUM )
164:   110       CONTINUE
165:          ELSE
166:             DO 140 J = 1, N
167:                IF( UDIAG ) THEN
168:                   SUM = ONE
169:                   DO 120 I = 2, MIN( N+1-J, K+1 )
170:                      SUM = SUM + ABS( AB( I, J ) )
171:   120             CONTINUE
172:                ELSE
173:                   SUM = ZERO
174:                   DO 130 I = 1, MIN( N+1-J, K+1 )
175:                      SUM = SUM + ABS( AB( I, J ) )
176:   130             CONTINUE
177:                END IF
178:                VALUE = MAX( VALUE, SUM )
179:   140       CONTINUE
180:          END IF
181:       ELSE IF( LSAME( NORM, 'I' ) ) THEN
182: *
183: *        Find normI(A).
184: *
185:          VALUE = ZERO
186:          IF( LSAME( UPLO, 'U' ) ) THEN
187:             IF( LSAME( DIAG, 'U' ) ) THEN
188:                DO 150 I = 1, N
189:                   WORK( I ) = ONE
190:   150          CONTINUE
191:                DO 170 J = 1, N
192:                   L = K + 1 - J
193:                   DO 160 I = MAX( 1, J-K ), J - 1
194:                      WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
195:   160             CONTINUE
196:   170          CONTINUE
197:             ELSE
198:                DO 180 I = 1, N
199:                   WORK( I ) = ZERO
200:   180          CONTINUE
201:                DO 200 J = 1, N
202:                   L = K + 1 - J
203:                   DO 190 I = MAX( 1, J-K ), J
204:                      WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
205:   190             CONTINUE
206:   200          CONTINUE
207:             END IF
208:          ELSE
209:             IF( LSAME( DIAG, 'U' ) ) THEN
210:                DO 210 I = 1, N
211:                   WORK( I ) = ONE
212:   210          CONTINUE
213:                DO 230 J = 1, N
214:                   L = 1 - J
215:                   DO 220 I = J + 1, MIN( N, J+K )
216:                      WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
217:   220             CONTINUE
218:   230          CONTINUE
219:             ELSE
220:                DO 240 I = 1, N
221:                   WORK( I ) = ZERO
222:   240          CONTINUE
223:                DO 260 J = 1, N
224:                   L = 1 - J
225:                   DO 250 I = J, MIN( N, J+K )
226:                      WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
227:   250             CONTINUE
228:   260          CONTINUE
229:             END IF
230:          END IF
231:          DO 270 I = 1, N
232:             VALUE = MAX( VALUE, WORK( I ) )
233:   270    CONTINUE
234:       ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
235: *
236: *        Find normF(A).
237: *
238:          IF( LSAME( UPLO, 'U' ) ) THEN
239:             IF( LSAME( DIAG, 'U' ) ) THEN
240:                SCALE = ONE
241:                SUM = N
242:                IF( K.GT.0 ) THEN
243:                   DO 280 J = 2, N
244:                      CALL DLASSQ( MIN( J-1, K ),
245:      $                            AB( MAX( K+2-J, 1 ), J ), 1, SCALE,
246:      $                            SUM )
247:   280             CONTINUE
248:                END IF
249:             ELSE
250:                SCALE = ZERO
251:                SUM = ONE
252:                DO 290 J = 1, N
253:                   CALL DLASSQ( MIN( J, K+1 ), AB( MAX( K+2-J, 1 ), J ),
254:      $                         1, SCALE, SUM )
255:   290          CONTINUE
256:             END IF
257:          ELSE
258:             IF( LSAME( DIAG, 'U' ) ) THEN
259:                SCALE = ONE
260:                SUM = N
261:                IF( K.GT.0 ) THEN
262:                   DO 300 J = 1, N - 1
263:                      CALL DLASSQ( MIN( N-J, K ), AB( 2, J ), 1, SCALE,
264:      $                            SUM )
265:   300             CONTINUE
266:                END IF
267:             ELSE
268:                SCALE = ZERO
269:                SUM = ONE
270:                DO 310 J = 1, N
271:                   CALL DLASSQ( MIN( N-J+1, K+1 ), AB( 1, J ), 1, SCALE,
272:      $                         SUM )
273:   310          CONTINUE
274:             END IF
275:          END IF
276:          VALUE = SCALE*SQRT( SUM )
277:       END IF
278: *
279:       DLANTB = VALUE
280:       RETURN
281: *
282: *     End of DLANTB
283: *
284:       END
285: