001:       SUBROUTINE CUNMRZ( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     January 2007
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            INFO, K, L, LDA, LDC, LWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  CUNMRZ overwrites the general complex M-by-N matrix C with
020: *
021: *                  SIDE = 'L'     SIDE = 'R'
022: *  TRANS = 'N':      Q * C          C * Q
023: *  TRANS = 'C':      Q**H * C       C * Q**H
024: *
025: *  where Q is a complex unitary matrix defined as the product of k
026: *  elementary reflectors
027: *
028: *        Q = H(1) H(2) . . . H(k)
029: *
030: *  as returned by CTZRZF. Q is of order M if SIDE = 'L' and of order N
031: *  if SIDE = 'R'.
032: *
033: *  Arguments
034: *  =========
035: *
036: *  SIDE    (input) CHARACTER*1
037: *          = 'L': apply Q or Q**H from the Left;
038: *          = 'R': apply Q or Q**H from the Right.
039: *
040: *  TRANS   (input) CHARACTER*1
041: *          = 'N':  No transpose, apply Q;
042: *          = 'C':  Conjugate transpose, apply Q**H.
043: *
044: *  M       (input) INTEGER
045: *          The number of rows of the matrix C. M >= 0.
046: *
047: *  N       (input) INTEGER
048: *          The number of columns of the matrix C. N >= 0.
049: *
050: *  K       (input) INTEGER
051: *          The number of elementary reflectors whose product defines
052: *          the matrix Q.
053: *          If SIDE = 'L', M >= K >= 0;
054: *          if SIDE = 'R', N >= K >= 0.
055: *
056: *  L       (input) INTEGER
057: *          The number of columns of the matrix A containing
058: *          the meaningful part of the Householder reflectors.
059: *          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
060: *
061: *  A       (input) COMPLEX array, dimension
062: *                               (LDA,M) if SIDE = 'L',
063: *                               (LDA,N) if SIDE = 'R'
064: *          The i-th row must contain the vector which defines the
065: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
066: *          CTZRZF in the last k rows of its array argument A.
067: *          A is modified by the routine but restored on exit.
068: *
069: *  LDA     (input) INTEGER
070: *          The leading dimension of the array A. LDA >= max(1,K).
071: *
072: *  TAU     (input) COMPLEX array, dimension (K)
073: *          TAU(i) must contain the scalar factor of the elementary
074: *          reflector H(i), as returned by CTZRZF.
075: *
076: *  C       (input/output) COMPLEX array, dimension (LDC,N)
077: *          On entry, the M-by-N matrix C.
078: *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
079: *
080: *  LDC     (input) INTEGER
081: *          The leading dimension of the array C. LDC >= max(1,M).
082: *
083: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
084: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
085: *
086: *  LWORK   (input) INTEGER
087: *          The dimension of the array WORK.
088: *          If SIDE = 'L', LWORK >= max(1,N);
089: *          if SIDE = 'R', LWORK >= max(1,M).
090: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
091: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
092: *          blocksize.
093: *
094: *          If LWORK = -1, then a workspace query is assumed; the routine
095: *          only calculates the optimal size of the WORK array, returns
096: *          this value as the first entry of the WORK array, and no error
097: *          message related to LWORK is issued by XERBLA.
098: *
099: *  INFO    (output) INTEGER
100: *          = 0:  successful exit
101: *          < 0:  if INFO = -i, the i-th argument had an illegal value
102: *
103: *  Further Details
104: *  ===============
105: *
106: *  Based on contributions by
107: *    A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
108: *
109: *  =====================================================================
110: *
111: *     .. Parameters ..
112:       INTEGER            NBMAX, LDT
113:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
114: *     ..
115: *     .. Local Scalars ..
116:       LOGICAL            LEFT, LQUERY, NOTRAN
117:       CHARACTER          TRANST
118:       INTEGER            I, I1, I2, I3, IB, IC, IINFO, IWS, JA, JC,
119:      $                   LDWORK, LWKOPT, MI, NB, NBMIN, NI, NQ, NW
120: *     ..
121: *     .. Local Arrays ..
122:       COMPLEX            T( LDT, NBMAX )
123: *     ..
124: *     .. External Functions ..
125:       LOGICAL            LSAME
126:       INTEGER            ILAENV
127:       EXTERNAL           LSAME, ILAENV
128: *     ..
129: *     .. External Subroutines ..
130:       EXTERNAL           CLARZB, CLARZT, CUNMR3, XERBLA
131: *     ..
132: *     .. Intrinsic Functions ..
133:       INTRINSIC          MAX, MIN
134: *     ..
135: *     .. Executable Statements ..
136: *
137: *     Test the input arguments
138: *
139:       INFO = 0
140:       LEFT = LSAME( SIDE, 'L' )
141:       NOTRAN = LSAME( TRANS, 'N' )
142:       LQUERY = ( LWORK.EQ.-1 )
143: *
144: *     NQ is the order of Q and NW is the minimum dimension of WORK
145: *
146:       IF( LEFT ) THEN
147:          NQ = M
148:          NW = MAX( 1, N )
149:       ELSE
150:          NQ = N
151:          NW = MAX( 1, M )
152:       END IF
153:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
154:          INFO = -1
155:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
156:          INFO = -2
157:       ELSE IF( M.LT.0 ) THEN
158:          INFO = -3
159:       ELSE IF( N.LT.0 ) THEN
160:          INFO = -4
161:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
162:          INFO = -5
163:       ELSE IF( L.LT.0 .OR. ( LEFT .AND. ( L.GT.M ) ) .OR.
164:      $         ( .NOT.LEFT .AND. ( L.GT.N ) ) ) THEN
165:          INFO = -6
166:       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
167:          INFO = -8
168:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
169:          INFO = -11
170:       END IF
171: *
172:       IF( INFO.EQ.0 ) THEN
173:          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
174:             LWKOPT = 1
175:          ELSE
176: *
177: *           Determine the block size.  NB may be at most NBMAX, where
178: *           NBMAX is used to define the local array T.
179: *
180:             NB = MIN( NBMAX, ILAENV( 1, 'CUNMRQ', SIDE // TRANS, M, N,
181:      $                               K, -1 ) )
182:             LWKOPT = NW*NB
183:          END IF
184:          WORK( 1 ) = LWKOPT
185: *
186:          IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
187:             INFO = -13
188:          END IF
189:       END IF
190: *
191:       IF( INFO.NE.0 ) THEN
192:          CALL XERBLA( 'CUNMRZ', -INFO )
193:          RETURN
194:       ELSE IF( LQUERY ) THEN
195:          RETURN
196:       END IF
197: *
198: *     Quick return if possible
199: *
200:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
201:          RETURN
202:       END IF
203: *
204: *     Determine the block size.  NB may be at most NBMAX, where NBMAX
205: *     is used to define the local array T.
206: *
207:       NB = MIN( NBMAX, ILAENV( 1, 'CUNMRQ', SIDE // TRANS, M, N, K,
208:      $     -1 ) )
209:       NBMIN = 2
210:       LDWORK = NW
211:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
212:          IWS = NW*NB
213:          IF( LWORK.LT.IWS ) THEN
214:             NB = LWORK / LDWORK
215:             NBMIN = MAX( 2, ILAENV( 2, 'CUNMRQ', SIDE // TRANS, M, N, K,
216:      $              -1 ) )
217:          END IF
218:       ELSE
219:          IWS = NW
220:       END IF
221: *
222:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
223: *
224: *        Use unblocked code
225: *
226:          CALL CUNMR3( SIDE, TRANS, M, N, K, L, A, LDA, TAU, C, LDC,
227:      $                WORK, IINFO )
228:       ELSE
229: *
230: *        Use blocked code
231: *
232:          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
233:      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
234:             I1 = 1
235:             I2 = K
236:             I3 = NB
237:          ELSE
238:             I1 = ( ( K-1 ) / NB )*NB + 1
239:             I2 = 1
240:             I3 = -NB
241:          END IF
242: *
243:          IF( LEFT ) THEN
244:             NI = N
245:             JC = 1
246:             JA = M - L + 1
247:          ELSE
248:             MI = M
249:             IC = 1
250:             JA = N - L + 1
251:          END IF
252: *
253:          IF( NOTRAN ) THEN
254:             TRANST = 'C'
255:          ELSE
256:             TRANST = 'N'
257:          END IF
258: *
259:          DO 10 I = I1, I2, I3
260:             IB = MIN( NB, K-I+1 )
261: *
262: *           Form the triangular factor of the block reflector
263: *           H = H(i+ib-1) . . . H(i+1) H(i)
264: *
265:             CALL CLARZT( 'Backward', 'Rowwise', L, IB, A( I, JA ), LDA,
266:      $                   TAU( I ), T, LDT )
267: *
268:             IF( LEFT ) THEN
269: *
270: *              H or H' is applied to C(i:m,1:n)
271: *
272:                MI = M - I + 1
273:                IC = I
274:             ELSE
275: *
276: *              H or H' is applied to C(1:m,i:n)
277: *
278:                NI = N - I + 1
279:                JC = I
280:             END IF
281: *
282: *           Apply H or H'
283: *
284:             CALL CLARZB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
285:      $                   IB, L, A( I, JA ), LDA, T, LDT, C( IC, JC ),
286:      $                   LDC, WORK, LDWORK )
287:    10    CONTINUE
288: *
289:       END IF
290: *
291:       WORK( 1 ) = LWKOPT
292: *
293:       RETURN
294: *
295: *     End of CUNMRZ
296: *
297:       END
298: