001:       SUBROUTINE CLARGV( N, X, INCX, Y, INCY, C, INCC )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       INTEGER            INCC, INCX, INCY, N
009: *     ..
010: *     .. Array Arguments ..
011:       REAL               C( * )
012:       COMPLEX            X( * ), Y( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  CLARGV generates a vector of complex plane rotations with real
019: *  cosines, determined by elements of the complex vectors x and y.
020: *  For i = 1,2,...,n
021: *
022: *     (        c(i)   s(i) ) ( x(i) ) = ( r(i) )
023: *     ( -conjg(s(i))  c(i) ) ( y(i) ) = (   0  )
024: *
025: *     where c(i)**2 + ABS(s(i))**2 = 1
026: *
027: *  The following conventions are used (these are the same as in CLARTG,
028: *  but differ from the BLAS1 routine CROTG):
029: *     If y(i)=0, then c(i)=1 and s(i)=0.
030: *     If x(i)=0, then c(i)=0 and s(i) is chosen so that r(i) is real.
031: *
032: *  Arguments
033: *  =========
034: *
035: *  N       (input) INTEGER
036: *          The number of plane rotations to be generated.
037: *
038: *  X       (input/output) COMPLEX array, dimension (1+(N-1)*INCX)
039: *          On entry, the vector x.
040: *          On exit, x(i) is overwritten by r(i), for i = 1,...,n.
041: *
042: *  INCX    (input) INTEGER
043: *          The increment between elements of X. INCX > 0.
044: *
045: *  Y       (input/output) COMPLEX array, dimension (1+(N-1)*INCY)
046: *          On entry, the vector y.
047: *          On exit, the sines of the plane rotations.
048: *
049: *  INCY    (input) INTEGER
050: *          The increment between elements of Y. INCY > 0.
051: *
052: *  C       (output) REAL array, dimension (1+(N-1)*INCC)
053: *          The cosines of the plane rotations.
054: *
055: *  INCC    (input) INTEGER
056: *          The increment between elements of C. INCC > 0.
057: *
058: *  Further Details
059: *  ======= =======
060: *
061: *  6-6-96 - Modified with a new algorithm by W. Kahan and J. Demmel
062: *
063: *  This version has a few statements commented out for thread safety
064: *  (machine parameters are computed on each entry). 10 feb 03, SJH.
065: *
066: *  =====================================================================
067: *
068: *     .. Parameters ..
069:       REAL               TWO, ONE, ZERO
070:       PARAMETER          ( TWO = 2.0E+0, ONE = 1.0E+0, ZERO = 0.0E+0 )
071:       COMPLEX            CZERO
072:       PARAMETER          ( CZERO = ( 0.0E+0, 0.0E+0 ) )
073: *     ..
074: *     .. Local Scalars ..
075: *     LOGICAL            FIRST
076:       INTEGER            COUNT, I, IC, IX, IY, J
077:       REAL               CS, D, DI, DR, EPS, F2, F2S, G2, G2S, SAFMIN,
078:      $                   SAFMN2, SAFMX2, SCALE
079:       COMPLEX            F, FF, FS, G, GS, R, SN
080: *     ..
081: *     .. External Functions ..
082:       REAL               SLAMCH, SLAPY2
083:       EXTERNAL           SLAMCH, SLAPY2
084: *     ..
085: *     .. Intrinsic Functions ..
086:       INTRINSIC          ABS, AIMAG, CMPLX, CONJG, INT, LOG, MAX, REAL,
087:      $                   SQRT
088: *     ..
089: *     .. Statement Functions ..
090:       REAL               ABS1, ABSSQ
091: *     ..
092: *     .. Save statement ..
093: *     SAVE               FIRST, SAFMX2, SAFMIN, SAFMN2
094: *     ..
095: *     .. Data statements ..
096: *     DATA               FIRST / .TRUE. /
097: *     ..
098: *     .. Statement Function definitions ..
099:       ABS1( FF ) = MAX( ABS( REAL( FF ) ), ABS( AIMAG( FF ) ) )
100:       ABSSQ( FF ) = REAL( FF )**2 + AIMAG( FF )**2
101: *     ..
102: *     .. Executable Statements ..
103: *
104: *     IF( FIRST ) THEN
105: *        FIRST = .FALSE.
106:          SAFMIN = SLAMCH( 'S' )
107:          EPS = SLAMCH( 'E' )
108:          SAFMN2 = SLAMCH( 'B' )**INT( LOG( SAFMIN / EPS ) /
109:      $            LOG( SLAMCH( 'B' ) ) / TWO )
110:          SAFMX2 = ONE / SAFMN2
111: *     END IF
112:       IX = 1
113:       IY = 1
114:       IC = 1
115:       DO 60 I = 1, N
116:          F = X( IX )
117:          G = Y( IY )
118: *
119: *        Use identical algorithm as in CLARTG
120: *
121:          SCALE = MAX( ABS1( F ), ABS1( G ) )
122:          FS = F
123:          GS = G
124:          COUNT = 0
125:          IF( SCALE.GE.SAFMX2 ) THEN
126:    10       CONTINUE
127:             COUNT = COUNT + 1
128:             FS = FS*SAFMN2
129:             GS = GS*SAFMN2
130:             SCALE = SCALE*SAFMN2
131:             IF( SCALE.GE.SAFMX2 )
132:      $         GO TO 10
133:          ELSE IF( SCALE.LE.SAFMN2 ) THEN
134:             IF( G.EQ.CZERO ) THEN
135:                CS = ONE
136:                SN = CZERO
137:                R = F
138:                GO TO 50
139:             END IF
140:    20       CONTINUE
141:             COUNT = COUNT - 1
142:             FS = FS*SAFMX2
143:             GS = GS*SAFMX2
144:             SCALE = SCALE*SAFMX2
145:             IF( SCALE.LE.SAFMN2 )
146:      $         GO TO 20
147:          END IF
148:          F2 = ABSSQ( FS )
149:          G2 = ABSSQ( GS )
150:          IF( F2.LE.MAX( G2, ONE )*SAFMIN ) THEN
151: *
152: *           This is a rare case: F is very small.
153: *
154:             IF( F.EQ.CZERO ) THEN
155:                CS = ZERO
156:                R = SLAPY2( REAL( G ), AIMAG( G ) )
157: *              Do complex/real division explicitly with two real
158: *              divisions
159:                D = SLAPY2( REAL( GS ), AIMAG( GS ) )
160:                SN = CMPLX( REAL( GS ) / D, -AIMAG( GS ) / D )
161:                GO TO 50
162:             END IF
163:             F2S = SLAPY2( REAL( FS ), AIMAG( FS ) )
164: *           G2 and G2S are accurate
165: *           G2 is at least SAFMIN, and G2S is at least SAFMN2
166:             G2S = SQRT( G2 )
167: *           Error in CS from underflow in F2S is at most
168: *           UNFL / SAFMN2 .lt. sqrt(UNFL*EPS) .lt. EPS
169: *           If MAX(G2,ONE)=G2, then F2 .lt. G2*SAFMIN,
170: *           and so CS .lt. sqrt(SAFMIN)
171: *           If MAX(G2,ONE)=ONE, then F2 .lt. SAFMIN
172: *           and so CS .lt. sqrt(SAFMIN)/SAFMN2 = sqrt(EPS)
173: *           Therefore, CS = F2S/G2S / sqrt( 1 + (F2S/G2S)**2 ) = F2S/G2S
174:             CS = F2S / G2S
175: *           Make sure abs(FF) = 1
176: *           Do complex/real division explicitly with 2 real divisions
177:             IF( ABS1( F ).GT.ONE ) THEN
178:                D = SLAPY2( REAL( F ), AIMAG( F ) )
179:                FF = CMPLX( REAL( F ) / D, AIMAG( F ) / D )
180:             ELSE
181:                DR = SAFMX2*REAL( F )
182:                DI = SAFMX2*AIMAG( F )
183:                D = SLAPY2( DR, DI )
184:                FF = CMPLX( DR / D, DI / D )
185:             END IF
186:             SN = FF*CMPLX( REAL( GS ) / G2S, -AIMAG( GS ) / G2S )
187:             R = CS*F + SN*G
188:          ELSE
189: *
190: *           This is the most common case.
191: *           Neither F2 nor F2/G2 are less than SAFMIN
192: *           F2S cannot overflow, and it is accurate
193: *
194:             F2S = SQRT( ONE+G2 / F2 )
195: *           Do the F2S(real)*FS(complex) multiply with two real
196: *           multiplies
197:             R = CMPLX( F2S*REAL( FS ), F2S*AIMAG( FS ) )
198:             CS = ONE / F2S
199:             D = F2 + G2
200: *           Do complex/real division explicitly with two real divisions
201:             SN = CMPLX( REAL( R ) / D, AIMAG( R ) / D )
202:             SN = SN*CONJG( GS )
203:             IF( COUNT.NE.0 ) THEN
204:                IF( COUNT.GT.0 ) THEN
205:                   DO 30 J = 1, COUNT
206:                      R = R*SAFMX2
207:    30             CONTINUE
208:                ELSE
209:                   DO 40 J = 1, -COUNT
210:                      R = R*SAFMN2
211:    40             CONTINUE
212:                END IF
213:             END IF
214:          END IF
215:    50    CONTINUE
216:          C( IC ) = CS
217:          Y( IY ) = SN
218:          X( IX ) = R
219:          IC = IC + INCC
220:          IY = IY + INCY
221:          IX = IX + INCX
222:    60 CONTINUE
223:       RETURN
224: *
225: *     End of CLARGV
226: *
227:       END
228: