001:       REAL FUNCTION CLA_SYRCOND_X( UPLO, N, A, LDA, AF, LDAF, IPIV, X,
002:      $                             INFO, WORK, RWORK )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          UPLO
016:       INTEGER            N, LDA, LDAF, INFO
017: *     ..
018: *     .. Array Arguments ..
019:       INTEGER            IPIV( * )
020:       COMPLEX            A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
021:       REAL               RWORK( * )
022: *
023: *     CLA_SYRCOND_X Computes the infinity norm condition number of
024: *     op(A) * diag(X) where X is a COMPLEX vector.
025: *     WORK is a COMPLEX workspace of size 2*N, and
026: *     RWORK is a REAL workspace of size 3*N.
027: *     ..
028: *     .. Local Scalars ..
029:       INTEGER            KASE
030:       REAL               AINVNM, ANORM, TMP
031:       INTEGER            I, J
032:       LOGICAL            UP
033:       COMPLEX            ZDUM
034: *     ..
035: *     .. Local Arrays ..
036:       INTEGER            ISAVE( 3 )
037: *     ..
038: *     .. External Functions ..
039:       LOGICAL            LSAME
040:       EXTERNAL           LSAME
041: *     ..
042: *     .. External Subroutines ..
043:       EXTERNAL           CLACN2, CSYTRS, XERBLA
044: *     ..
045: *     .. Intrinsic Functions ..
046:       INTRINSIC          ABS, MAX
047: *     ..
048: *     .. Statement Functions ..
049:       REAL               CABS1
050: *     ..
051: *     .. Statement Function Definitions ..
052:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
053: *     ..
054: *     .. Executable Statements ..
055: *
056:       CLA_SYRCOND_X = 0.0E+0
057: *
058:       INFO = 0
059:       IF( N.LT.0 ) THEN
060:          INFO = -2
061:       END IF
062:       IF( INFO.NE.0 ) THEN
063:          CALL XERBLA( 'CLA_SYRCOND_X', -INFO )
064:          RETURN
065:       END IF
066:       UP = .FALSE.
067:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
068: *
069: *     Compute norm of op(A)*op2(C).
070: *
071:       ANORM = 0.0
072:       IF ( UP ) THEN
073:          DO I = 1, N
074:             TMP = 0.0E+0
075:             DO J = 1, N
076:                IF ( I.GT.J ) THEN
077:                   TMP = TMP + CABS1( A( J, I ) * X( J ) )
078:                ELSE
079:                   TMP = TMP + CABS1( A( I, J ) * X( J ) )
080:                END IF
081:             END DO
082:             RWORK( 2*N+I ) = TMP
083:             ANORM = MAX( ANORM, TMP )
084:          END DO
085:       ELSE
086:          DO I = 1, N
087:             TMP = 0.0E+0
088:             DO J = 1, N
089:                IF ( I.LT.J ) THEN
090:                   TMP = TMP + CABS1( A( J, I ) * X( J ) )
091:                ELSE
092:                   TMP = TMP + CABS1( A( I, J ) * X( J ) )
093:                END IF
094:             END DO
095:             RWORK( 2*N+I ) = TMP
096:             ANORM = MAX( ANORM, TMP )
097:          END DO
098:       END IF
099: *
100: *     Quick return if possible.
101: *
102:       IF( N.EQ.0 ) THEN
103:          CLA_SYRCOND_X = 1.0E+0
104:          RETURN
105:       ELSE IF( ANORM .EQ. 0.0E+0 ) THEN
106:          RETURN
107:       END IF
108: *
109: *     Estimate the norm of inv(op(A)).
110: *
111:       AINVNM = 0.0E+0
112: *
113:       KASE = 0
114:    10 CONTINUE
115:       CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
116:       IF( KASE.NE.0 ) THEN
117:          IF( KASE.EQ.2 ) THEN
118: *
119: *           Multiply by R.
120: *
121:             DO I = 1, N
122:                WORK( I ) = WORK( I ) * RWORK( 2*N+I )
123:             END DO
124: *
125:             IF ( UP ) THEN
126:                CALL CSYTRS( 'U', N, 1, AF, LDAF, IPIV,
127:      $            WORK, N, INFO )
128:             ELSE
129:                CALL CSYTRS( 'L', N, 1, AF, LDAF, IPIV,
130:      $            WORK, N, INFO )
131:             ENDIF
132: *
133: *           Multiply by inv(X).
134: *
135:             DO I = 1, N
136:                WORK( I ) = WORK( I ) / X( I )
137:             END DO
138:          ELSE
139: *
140: *           Multiply by inv(X').
141: *
142:             DO I = 1, N
143:                WORK( I ) = WORK( I ) / X( I )
144:             END DO
145: *
146:             IF ( UP ) THEN
147:                CALL CSYTRS( 'U', N, 1, AF, LDAF, IPIV,
148:      $            WORK, N, INFO )
149:             ELSE
150:                CALL CSYTRS( 'L', N, 1, AF, LDAF, IPIV,
151:      $            WORK, N, INFO )
152:             END IF
153: *
154: *           Multiply by R.
155: *
156:             DO I = 1, N
157:                WORK( I ) = WORK( I ) * RWORK( 2*N+I )
158:             END DO
159:          END IF
160:          GO TO 10
161:       END IF
162: *
163: *     Compute the estimate of the reciprocal condition number.
164: *
165:       IF( AINVNM .NE. 0.0E+0 )
166:      $   CLA_SYRCOND_X = 1.0E+0 / AINVNM
167: *
168:       RETURN
169: *
170:       END
171: