001:       SUBROUTINE CLA_SYAMV( UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y,
002:      $                      INCY )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       REAL               ALPHA, BETA
016:       INTEGER            INCX, INCY, LDA, N
017:       INTEGER            UPLO
018: *     ..
019: *     .. Array Arguments ..
020:       COMPLEX            A( LDA, * ), X( * )
021:       REAL               Y( * )
022: *     ..
023: *
024: *  Purpose
025: *  =======
026: *
027: *  CLA_SYAMV  performs the matrix-vector operation
028: *
029: *          y := alpha*abs(A)*abs(x) + beta*abs(y),
030: *
031: *  where alpha and beta are scalars, x and y are vectors and A is an
032: *  n by n symmetric matrix.
033: *
034: *  This function is primarily used in calculating error bounds.
035: *  To protect against underflow during evaluation, components in
036: *  the resulting vector are perturbed away from zero by (N+1)
037: *  times the underflow threshold.  To prevent unnecessarily large
038: *  errors for block-structure embedded in general matrices,
039: *  "symbolically" zero components are not perturbed.  A zero
040: *  entry is considered "symbolic" if all multiplications involved
041: *  in computing that entry have at least one zero multiplicand.
042: *
043: *  Parameters
044: *  ==========
045: *
046: *  UPLO   - INTEGER
047: *           On entry, UPLO specifies whether the upper or lower
048: *           triangular part of the array A is to be referenced as
049: *           follows:
050: *
051: *              UPLO = BLAS_UPPER   Only the upper triangular part of A
052: *                                  is to be referenced.
053: *
054: *              UPLO = BLAS_LOWER   Only the lower triangular part of A
055: *                                  is to be referenced.
056: *
057: *           Unchanged on exit.
058: *
059: *  N      - INTEGER.
060: *           On entry, N specifies the number of columns of the matrix A.
061: *           N must be at least zero.
062: *           Unchanged on exit.
063: *
064: *  ALPHA  - REAL            .
065: *           On entry, ALPHA specifies the scalar alpha.
066: *           Unchanged on exit.
067: *
068: *  A      - COMPLEX             array of DIMENSION ( LDA, n ).
069: *           Before entry, the leading m by n part of the array A must
070: *           contain the matrix of coefficients.
071: *           Unchanged on exit.
072: *
073: *  LDA    - INTEGER.
074: *           On entry, LDA specifies the first dimension of A as declared
075: *           in the calling (sub) program. LDA must be at least
076: *           max( 1, n ).
077: *           Unchanged on exit.
078: *
079: *  X      - COMPLEX             array of DIMENSION at least
080: *           ( 1 + ( n - 1 )*abs( INCX ) )
081: *           Before entry, the incremented array X must contain the
082: *           vector x.
083: *           Unchanged on exit.
084: *
085: *  INCX   - INTEGER.
086: *           On entry, INCX specifies the increment for the elements of
087: *           X. INCX must not be zero.
088: *           Unchanged on exit.
089: *
090: *  BETA   - REAL            .
091: *           On entry, BETA specifies the scalar beta. When BETA is
092: *           supplied as zero then Y need not be set on input.
093: *           Unchanged on exit.
094: *
095: *  Y      - REAL             array of DIMENSION at least
096: *           ( 1 + ( n - 1 )*abs( INCY ) )
097: *           Before entry with BETA non-zero, the incremented array Y
098: *           must contain the vector y. On exit, Y is overwritten by the
099: *           updated vector y.
100: *
101: *  INCY   - INTEGER.
102: *           On entry, INCY specifies the increment for the elements of
103: *           Y. INCY must not be zero.
104: *           Unchanged on exit.
105: *
106: *
107: *  Level 2 Blas routine.
108: *
109: *  -- Written on 22-October-1986.
110: *     Jack Dongarra, Argonne National Lab.
111: *     Jeremy Du Croz, Nag Central Office.
112: *     Sven Hammarling, Nag Central Office.
113: *     Richard Hanson, Sandia National Labs.
114: *  -- Modified for the absolute-value product, April 2006
115: *     Jason Riedy, UC Berkeley
116: *
117: *     ..
118: *     .. Parameters ..
119:       REAL               ONE, ZERO
120:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
121: *     ..
122: *     .. Local Scalars ..
123:       LOGICAL            SYMB_ZERO
124:       REAL               TEMP, SAFE1
125:       INTEGER            I, INFO, IY, J, JX, KX, KY
126:       COMPLEX            ZDUM
127: *     ..
128: *     .. External Subroutines ..
129:       EXTERNAL           XERBLA, SLAMCH
130:       REAL               SLAMCH
131: *     ..
132: *     .. External Functions ..
133:       EXTERNAL           ILAUPLO
134:       INTEGER            ILAUPLO
135: *     ..
136: *     .. Intrinsic Functions ..
137:       INTRINSIC          MAX, ABS, SIGN, REAL, AIMAG
138: *     ..
139: *     .. Statement Functions ..
140:       REAL               CABS1
141: *     ..
142: *     .. Statement Function Definitions ..
143:       CABS1( ZDUM ) = ABS( REAL ( ZDUM ) ) + ABS( AIMAG ( ZDUM ) )
144: *     ..
145: *     .. Executable Statements ..
146: *
147: *     Test the input parameters.
148: *
149:       INFO = 0
150:       IF     ( UPLO.NE.ILAUPLO( 'U' ) .AND.
151:      $         UPLO.NE.ILAUPLO( 'L' ) )THEN
152:          INFO = 1
153:       ELSE IF( N.LT.0 )THEN
154:          INFO = 2
155:       ELSE IF( LDA.LT.MAX( 1, N ) )THEN
156:          INFO = 5
157:       ELSE IF( INCX.EQ.0 )THEN
158:          INFO = 7
159:       ELSE IF( INCY.EQ.0 )THEN
160:          INFO = 10
161:       END IF
162:       IF( INFO.NE.0 )THEN
163:          CALL XERBLA( 'SSYMV ', INFO )
164:          RETURN
165:       END IF
166: *
167: *     Quick return if possible.
168: *
169:       IF( ( N.EQ.0 ).OR.( ( ALPHA.EQ.ZERO ).AND.( BETA.EQ.ONE ) ) )
170:      $   RETURN
171: *
172: *     Set up the start points in  X  and  Y.
173: *
174:       IF( INCX.GT.0 )THEN
175:          KX = 1
176:       ELSE
177:          KX = 1 - ( N - 1 )*INCX
178:       END IF
179:       IF( INCY.GT.0 )THEN
180:          KY = 1
181:       ELSE
182:          KY = 1 - ( N - 1 )*INCY
183:       END IF
184: *
185: *     Set SAFE1 essentially to be the underflow threshold times the
186: *     number of additions in each row.
187: *
188:       SAFE1 = SLAMCH( 'Safe minimum' )
189:       SAFE1 = (N+1)*SAFE1
190: *
191: *     Form  y := alpha*abs(A)*abs(x) + beta*abs(y).
192: *
193: *     The O(N^2) SYMB_ZERO tests could be replaced by O(N) queries to
194: *     the inexact flag.  Still doesn't help change the iteration order
195: *     to per-column.
196: *
197:       IY = KY
198:       IF ( INCX.EQ.1 ) THEN
199:          DO I = 1, N
200:             IF ( BETA .EQ. ZERO ) THEN
201:                SYMB_ZERO = .TRUE.
202:                Y( IY ) = 0.0
203:             ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
204:                SYMB_ZERO = .TRUE.
205:             ELSE
206:                SYMB_ZERO = .FALSE.
207:                Y( IY ) = BETA * ABS( Y( IY ) )
208:             END IF
209:             IF ( ALPHA .NE. ZERO ) THEN
210:                DO J = 1, N
211:                   IF ( UPLO .EQ. ILAUPLO( 'U' ) ) THEN
212:                      IF ( I .LE. J ) THEN
213:                         TEMP = CABS1( A( I, J ) )
214:                      ELSE
215:                         TEMP = CABS1( A( J, I ) )
216:                      END IF
217:                   ELSE
218:                      IF ( I .GE. J ) THEN
219:                         TEMP = CABS1( A( I, J ) )
220:                      ELSE
221:                         TEMP = CABS1( A( J, I ) )
222:                      END IF
223:                   END IF
224: 
225:                   SYMB_ZERO = SYMB_ZERO .AND.
226:      $                 ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
227: 
228:                   Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
229:                END DO
230:             END IF
231: 
232:             IF ( .NOT.SYMB_ZERO )
233:      $           Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
234: 
235:             IY = IY + INCY
236:          END DO
237:       ELSE
238:          DO I = 1, N
239:             IF ( BETA .EQ. ZERO ) THEN
240:                SYMB_ZERO = .TRUE.
241:                Y( IY ) = 0.0
242:             ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
243:                SYMB_ZERO = .TRUE.
244:             ELSE
245:                SYMB_ZERO = .FALSE.
246:                Y( IY ) = BETA * ABS( Y( IY ) )
247:             END IF
248:             JX = KX
249:             IF ( ALPHA .NE. ZERO ) THEN
250:                DO J = 1, N
251:                   IF ( UPLO .EQ. ILAUPLO( 'U' ) ) THEN
252:                      IF ( I .LE. J ) THEN
253:                         TEMP = CABS1( A( I, J ) )
254:                      ELSE
255:                         TEMP = CABS1( A( J, I ) )
256:                      END IF
257:                   ELSE
258:                      IF ( I .GE. J ) THEN
259:                         TEMP = CABS1( A( I, J ) )
260:                      ELSE
261:                         TEMP = CABS1( A( J, I ) )
262:                      END IF
263:                   END IF
264: 
265:                   SYMB_ZERO = SYMB_ZERO .AND.
266:      $                 ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
267: 
268:                   Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
269:                   JX = JX + INCX
270:                END DO
271:             END IF
272: 
273:             IF ( .NOT.SYMB_ZERO )
274:      $           Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
275: 
276:             IY = IY + INCY
277:          END DO
278:       END IF
279: *
280:       RETURN
281: *
282: *     End of CLA_SYAMV
283: *
284:       END
285: