001:       REAL FUNCTION CLA_HERCOND_C( UPLO, N, A, LDA, AF, LDAF, IPIV, C,
002:      $                             CAPPLY, INFO, WORK, RWORK )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          UPLO
016:       LOGICAL            CAPPLY
017:       INTEGER            N, LDA, LDAF, INFO
018: *     ..
019: *     .. Array Arguments ..
020:       INTEGER            IPIV( * )
021:       COMPLEX            A( LDA, * ), AF( LDAF, * ), WORK( * )
022:       REAL               C ( * ), RWORK( * )
023: *
024: *     CLA_HERCOND_C computes the infinity norm condition number of
025: *     op(A) * inv(diag(C)) where C is a REAL vector.
026: *     WORK is a COMPLEX workspace of size 2*N, and
027: *     RWORK is a REAL workspace of size 3*N.
028: *     ..
029: *     .. Local Scalars ..
030:       INTEGER            KASE, I, J
031:       REAL               AINVNM, ANORM, TMP
032:       LOGICAL            UP
033:       COMPLEX            ZDUM
034: *     ..
035: *     .. Local Arrays ..
036:       INTEGER            ISAVE( 3 )
037: *     ..
038: *     .. External Functions ..
039:       LOGICAL            LSAME
040:       EXTERNAL           LSAME
041: *     ..
042: *     .. External Subroutines ..
043:       EXTERNAL           CLACN2, CHETRS, XERBLA
044: *     ..
045: *     .. Intrinsic Functions ..
046:       INTRINSIC          ABS, MAX
047: *     ..
048: *     .. Statement Functions ..
049:       REAL               CABS1
050: *     ..
051: *     .. Statement Function Definitions ..
052:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
053: *     ..
054: *     .. Executable Statements ..
055: *
056:       CLA_HERCOND_C = 0.0E+0
057: *
058:       INFO = 0
059:       IF( N.LT.0 ) THEN
060:          INFO = -2
061:       END IF
062:       IF( INFO.NE.0 ) THEN
063:          CALL XERBLA( 'CLA_HERCOND_C', -INFO )
064:          RETURN
065:       END IF
066:       UP = .FALSE.
067:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
068: *
069: *     Compute norm of op(A)*op2(C).
070: *
071:       ANORM = 0.0E+0
072:       IF ( UP ) THEN
073:          DO I = 1, N
074:             TMP = 0.0E+0
075:             IF ( CAPPLY ) THEN
076:                DO J = 1, N
077:                   IF ( I.GT.J ) THEN
078:                      TMP = TMP + CABS1( A( J, I ) ) / C( J )
079:                   ELSE
080:                      TMP = TMP + CABS1( A( I, J ) ) / C( J )
081:                   END IF
082:                END DO
083:             ELSE
084:                DO J = 1, N
085:                   IF ( I.GT.J ) THEN
086:                      TMP = TMP + CABS1( A( J, I ) )
087:                   ELSE
088:                      TMP = TMP + CABS1( A( I, J ) )
089:                   END IF
090:                END DO
091:             END IF
092:             RWORK( 2*N+I ) = TMP
093:             ANORM = MAX( ANORM, TMP )
094:          END DO
095:       ELSE
096:          DO I = 1, N
097:             TMP = 0.0E+0
098:             IF ( CAPPLY ) THEN
099:                DO J = 1, N
100:                   IF ( I.LT.J ) THEN
101:                      TMP = TMP + CABS1( A( J, I ) ) / C( J )
102:                   ELSE
103:                      TMP = TMP + CABS1( A( I, J ) ) / C( J )
104:                   END IF
105:                END DO
106:             ELSE
107:                DO J = 1, N
108:                   IF ( I.LT.J ) THEN
109:                      TMP = TMP + CABS1( A( J, I ) )
110:                   ELSE
111:                      TMP = TMP + CABS1( A( I, J ) )
112:                   END IF
113:                END DO
114:             END IF
115:             RWORK( 2*N+I ) = TMP
116:             ANORM = MAX( ANORM, TMP )
117:          END DO
118:       END IF
119: *
120: *     Quick return if possible.
121: *
122:       IF( N.EQ.0 ) THEN
123:          CLA_HERCOND_C = 1.0E+0
124:          RETURN
125:       ELSE IF( ANORM .EQ. 0.0E+0 ) THEN
126:          RETURN
127:       END IF
128: *
129: *     Estimate the norm of inv(op(A)).
130: *
131:       AINVNM = 0.0E+0
132: *
133:       KASE = 0
134:    10 CONTINUE
135:       CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
136:       IF( KASE.NE.0 ) THEN
137:          IF( KASE.EQ.2 ) THEN
138: *
139: *           Multiply by R.
140: *
141:             DO I = 1, N
142:                WORK( I ) = WORK( I ) * RWORK( 2*N+I )
143:             END DO
144: *
145:             IF ( UP ) THEN
146:                CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
147:      $            WORK, N, INFO )
148:             ELSE
149:                CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
150:      $            WORK, N, INFO )
151:             ENDIF
152: *
153: *           Multiply by inv(C).
154: *
155:             IF ( CAPPLY ) THEN
156:                DO I = 1, N
157:                   WORK( I ) = WORK( I ) * C( I )
158:                END DO
159:             END IF
160:          ELSE
161: *
162: *           Multiply by inv(C').
163: *
164:             IF ( CAPPLY ) THEN
165:                DO I = 1, N
166:                   WORK( I ) = WORK( I ) * C( I )
167:                END DO
168:             END IF
169: *
170:             IF ( UP ) THEN
171:                CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
172:      $            WORK, N, INFO )
173:             ELSE
174:                CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
175:      $            WORK, N, INFO )
176:             END IF
177: *
178: *           Multiply by R.
179: *
180:             DO I = 1, N
181:                WORK( I ) = WORK( I ) * RWORK( 2*N+I )
182:             END DO
183:          END IF
184:          GO TO 10
185:       END IF
186: *
187: *     Compute the estimate of the reciprocal condition number.
188: *
189:       IF( AINVNM .NE. 0.0E+0 )
190:      $   CLA_HERCOND_C = 1.0E+0 / AINVNM
191: *
192:       RETURN
193: *
194:       END
195: