001:       SUBROUTINE CHPEV( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, RWORK,
002:      $                  INFO )
003: *
004: *  -- LAPACK driver routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          JOBZ, UPLO
010:       INTEGER            INFO, LDZ, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               RWORK( * ), W( * )
014:       COMPLEX            AP( * ), WORK( * ), Z( LDZ, * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  CHPEV computes all the eigenvalues and, optionally, eigenvectors of a
021: *  complex Hermitian matrix in packed storage.
022: *
023: *  Arguments
024: *  =========
025: *
026: *  JOBZ    (input) CHARACTER*1
027: *          = 'N':  Compute eigenvalues only;
028: *          = 'V':  Compute eigenvalues and eigenvectors.
029: *
030: *  UPLO    (input) CHARACTER*1
031: *          = 'U':  Upper triangle of A is stored;
032: *          = 'L':  Lower triangle of A is stored.
033: *
034: *  N       (input) INTEGER
035: *          The order of the matrix A.  N >= 0.
036: *
037: *  AP      (input/output) COMPLEX array, dimension (N*(N+1)/2)
038: *          On entry, the upper or lower triangle of the Hermitian matrix
039: *          A, packed columnwise in a linear array.  The j-th column of A
040: *          is stored in the array AP as follows:
041: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
042: *          if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
043: *
044: *          On exit, AP is overwritten by values generated during the
045: *          reduction to tridiagonal form.  If UPLO = 'U', the diagonal
046: *          and first superdiagonal of the tridiagonal matrix T overwrite
047: *          the corresponding elements of A, and if UPLO = 'L', the
048: *          diagonal and first subdiagonal of T overwrite the
049: *          corresponding elements of A.
050: *
051: *  W       (output) REAL array, dimension (N)
052: *          If INFO = 0, the eigenvalues in ascending order.
053: *
054: *  Z       (output) COMPLEX array, dimension (LDZ, N)
055: *          If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
056: *          eigenvectors of the matrix A, with the i-th column of Z
057: *          holding the eigenvector associated with W(i).
058: *          If JOBZ = 'N', then Z is not referenced.
059: *
060: *  LDZ     (input) INTEGER
061: *          The leading dimension of the array Z.  LDZ >= 1, and if
062: *          JOBZ = 'V', LDZ >= max(1,N).
063: *
064: *  WORK    (workspace) COMPLEX array, dimension (max(1, 2*N-1))
065: *
066: *  RWORK   (workspace) REAL array, dimension (max(1, 3*N-2))
067: *
068: *  INFO    (output) INTEGER
069: *          = 0:  successful exit.
070: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
071: *          > 0:  if INFO = i, the algorithm failed to converge; i
072: *                off-diagonal elements of an intermediate tridiagonal
073: *                form did not converge to zero.
074: *
075: *  =====================================================================
076: *
077: *     .. Parameters ..
078:       REAL               ZERO, ONE
079:       PARAMETER          ( ZERO = 0.0E0, ONE = 1.0E0 )
080: *     ..
081: *     .. Local Scalars ..
082:       LOGICAL            WANTZ
083:       INTEGER            IINFO, IMAX, INDE, INDRWK, INDTAU, INDWRK,
084:      $                   ISCALE
085:       REAL               ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
086:      $                   SMLNUM
087: *     ..
088: *     .. External Functions ..
089:       LOGICAL            LSAME
090:       REAL               CLANHP, SLAMCH
091:       EXTERNAL           LSAME, CLANHP, SLAMCH
092: *     ..
093: *     .. External Subroutines ..
094:       EXTERNAL           CHPTRD, CSSCAL, CSTEQR, CUPGTR, SSCAL, SSTERF,
095:      $                   XERBLA
096: *     ..
097: *     .. Intrinsic Functions ..
098:       INTRINSIC          SQRT
099: *     ..
100: *     .. Executable Statements ..
101: *
102: *     Test the input parameters.
103: *
104:       WANTZ = LSAME( JOBZ, 'V' )
105: *
106:       INFO = 0
107:       IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
108:          INFO = -1
109:       ELSE IF( .NOT.( LSAME( UPLO, 'L' ) .OR. LSAME( UPLO, 'U' ) ) )
110:      $          THEN
111:          INFO = -2
112:       ELSE IF( N.LT.0 ) THEN
113:          INFO = -3
114:       ELSE IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
115:          INFO = -7
116:       END IF
117: *
118:       IF( INFO.NE.0 ) THEN
119:          CALL XERBLA( 'CHPEV ', -INFO )
120:          RETURN
121:       END IF
122: *
123: *     Quick return if possible
124: *
125:       IF( N.EQ.0 )
126:      $   RETURN
127: *
128:       IF( N.EQ.1 ) THEN
129:          W( 1 ) = AP( 1 )
130:          RWORK( 1 ) = 1
131:          IF( WANTZ )
132:      $      Z( 1, 1 ) = ONE
133:          RETURN
134:       END IF
135: *
136: *     Get machine constants.
137: *
138:       SAFMIN = SLAMCH( 'Safe minimum' )
139:       EPS = SLAMCH( 'Precision' )
140:       SMLNUM = SAFMIN / EPS
141:       BIGNUM = ONE / SMLNUM
142:       RMIN = SQRT( SMLNUM )
143:       RMAX = SQRT( BIGNUM )
144: *
145: *     Scale matrix to allowable range, if necessary.
146: *
147:       ANRM = CLANHP( 'M', UPLO, N, AP, RWORK )
148:       ISCALE = 0
149:       IF( ANRM.GT.ZERO .AND. ANRM.LT.RMIN ) THEN
150:          ISCALE = 1
151:          SIGMA = RMIN / ANRM
152:       ELSE IF( ANRM.GT.RMAX ) THEN
153:          ISCALE = 1
154:          SIGMA = RMAX / ANRM
155:       END IF
156:       IF( ISCALE.EQ.1 ) THEN
157:          CALL CSSCAL( ( N*( N+1 ) ) / 2, SIGMA, AP, 1 )
158:       END IF
159: *
160: *     Call CHPTRD to reduce Hermitian packed matrix to tridiagonal form.
161: *
162:       INDE = 1
163:       INDTAU = 1
164:       CALL CHPTRD( UPLO, N, AP, W, RWORK( INDE ), WORK( INDTAU ),
165:      $             IINFO )
166: *
167: *     For eigenvalues only, call SSTERF.  For eigenvectors, first call
168: *     CUPGTR to generate the orthogonal matrix, then call CSTEQR.
169: *
170:       IF( .NOT.WANTZ ) THEN
171:          CALL SSTERF( N, W, RWORK( INDE ), INFO )
172:       ELSE
173:          INDWRK = INDTAU + N
174:          CALL CUPGTR( UPLO, N, AP, WORK( INDTAU ), Z, LDZ,
175:      $                WORK( INDWRK ), IINFO )
176:          INDRWK = INDE + N
177:          CALL CSTEQR( JOBZ, N, W, RWORK( INDE ), Z, LDZ,
178:      $                RWORK( INDRWK ), INFO )
179:       END IF
180: *
181: *     If matrix was scaled, then rescale eigenvalues appropriately.
182: *
183:       IF( ISCALE.EQ.1 ) THEN
184:          IF( INFO.EQ.0 ) THEN
185:             IMAX = N
186:          ELSE
187:             IMAX = INFO - 1
188:          END IF
189:          CALL SSCAL( IMAX, ONE / SIGMA, W, 1 )
190:       END IF
191: *
192:       RETURN
193: *
194: *     End of CHPEV
195: *
196:       END
197: