subroutine rebakb(nm,n,b,dl,m,z)
c
      integer i,j,k,m,n,nm
      real b(nm,n),dl(n),z(nm,m)
      real x
c
c     this subroutine is a translation of the algol procedure rebakb,
c     num. math. 11, 99-110(1968) by martin and wilkinson.
c     handbook for auto. comp., vol.ii-linear algebra, 303-314(1971).
c
c     this subroutine forms the eigenvectors of a generalized
c     symmetric eigensystem by back transforming those of the
c     derived symmetric matrix determined by  reduc2.
c
c     on input
c
c        nm must be set to the row dimension of two-dimensional
c          array parameters as declared in the calling program
c          dimension statement.
c
c        n is the order of the matrix system.
c
c        b contains information about the similarity transformation
c          (cholesky decomposition) used in the reduction by  reduc2
c          in its strict lower triangle.
c
c        dl contains further information about the transformation.
c
c        m is the number of eigenvectors to be back transformed.
c
c        z contains the eigenvectors to be back transformed
c          in its first m columns.
c
c     on output
c
c        z contains the transformed eigenvectors
c          in its first m columns.
c
c     Questions and comments should be directed to Alan K. Cline,
c     Pleasant Valley Software, 8603 Altus Cove, Austin, TX 78759.
c     Electronic mail to cline@cs.utexas.edu.
c
c     this version dated january 1989. (for the IBM 3090vf)
c
c     ------------------------------------------------------------------
c
      call xuflow(0)
      do 100 j = 1, m
c     .......... for i=n step -1 until 1 do -- ..........
         do 100 i = n, 1, -1
            x = dl(i) * z(i,j)
            do 60 k = 1, i-1
   60          x = x + b(i,k) * z(k,j)
            z(i,j) = x
  100 continue
c
      return
      end